Bonjour,

J'ai programmé l'indice de coppock comme Orion l'a fait en page 7 mais cela ne marche pas et Graph AT pro m'indique un message d'erreur "L'argument doit être historisé" lorsque je teste la formule.

Si Quelqu'un peut m'aider a remettre cela dans l'ordre.

Thanks

Bonsoir Foki.

Oui cela a déjà été expliqué plusieurs fois ici.
Dorénavant GrapheAT Pro vérifie à la compilation des règles si des variables qui doivent être historisées le sont bien, dans le cas négatif : message d'erreur.
C'est bien pratique quand-même.
Pour le cas qui nous intéresse ici il faut écrire :

--------------------------------------------
ROC11=100*(CLOTURE-CLOTURE(11))/CLOTURE(11)
ROC14=100*(CLOTURE-CLOTURE(14))/CLOTURE(14)

SROC(0) = ROC11 + ROC14

INDICECOPPOCK = PONDERE(SROC,10)
--------------------------------------------

Comment veux-tu qu'il puisse calculer INDICECOPPOCK qui est une moyenne pondérée sur 10 périodes si SROC n'est pas historisée mais ne contient qu'une valeur?

Un très grand merci, Smallcap.

Je suis niveau 0 en soft et je dois dire que la page "Programmation Graph AT Pro" m'est très très utile car elle me permet de rajouter et tester de nouveaux indicateurs dans ce log que je trouve d'un excellent rapport : Qualité/Prix.

Bonsoir Smallcaps,

Merci mille fois pour ton aide précieuse, pour l'indicateur EASE OF MOVEMENT.

Chris

Bonjour à tous,

En complément de l’excellent travail de développement de SMALLCAPS sur la droite de régression linéaire et ses canaux. Et pour apporter aussi un plus à l’article publicitaire paru dans le dernier numéro d’Action Future. Je souhaitais apporter une brique à l’édifice GRAPHAT PRO, en vous proposant une version de l’indicateur R CARRE. Il découle naturellement des programmations ayant pour base la régression linéaire.

// R Carré (Coefficient de corrélation)

somx = 0
somy = 0
somxx = 0
somxy = 0
somyy = 0
Pour P1 Cours
somx = somx+RANGPOUR
somy = somy+Cloture
somxx = somxx+RANGPOUR*RANGPOUR
somxy = somxy+RANGPOUR*Cloture
somyy = somyy+Cloture*Cloture
FinPour

a = (P1*somxy-somx*somy)
b = (P1*somxx-somx*somx)
c = (P1*somyy-somy*somy)
R2 = (a/racine(b*c))^2

Trig=0.27
Trig1=0.79

//Fin prog R Carré

Les trigger sont disposés à ces niveaux, pour être conformes aux recommandations de Steve Achelis parues dans « L’analyse technique de A à Z ».

Pour déterminer si la tendance d’une droite de régression linéaire sur n périodes est significative il faut afficher le R2 et ce reporter au tableau ci-dessous qui montre les valeurs du R2 exigées, pour obtenir un niveau de confiance de 95%.
On peut même tenter d’initier une position à court terme contre la tendance dominante si le R2 s’infléchit à des niveaux extrêmes (0.80)

Nb Périodes----Valeur R2 pour 95% Confiance
5---------------------0.77
10--------------------0.40
14--------------------0.27 (cas présenté)
20--------------------0.20
25--------------------0.16
30--------------------0.13
50--------------------0.08
60--------------------0.06
120-------------------0.03



Exemple sur AGF:


Après avoir touché une première fois sa résistance le 23/02/04, AGF a commencé sa descente matérialisée par une droite de régression linéaire à 14 jours. Au 15/03/04 le R Carré(14) ascendant dépasse le niveau 0.27 indiquant une tendance avérée. Le 23/03/04 le R Carré(14) atteint le niveau extrème de 0.8 indiquant un possible retournement de tendance. Les jours suivants confirme ce changement.

Toute critique est la bienvenue pour améliorer le bazar...

Suite du précédent post. Test de détection des niveaux extremes du RCarré dans le nouveau module statistique de GRAPHAT PRO.




Par contre je n'arrive pas à programmer le passage d'un niveau par exemple:

De inférieur à 0.27 à supérieur à 0.27 sur une ou deux périodes...

Une aide est bienvenue

citation :

---

Citation de chctrader

...

Par contre je n'arrive pas à programmer le passage d'un niveau par exemple:

De inférieur à 0.27 à supérieur à 0.27 sur une ou deux périodes...

Une aide est bienvenue

---

Tu peux tester ton indicateur R2 directement dans les statistiques sans remettre le code :

Si CROISE(R2.R2,0.27)>0 Alors Selection

En espérant que cela répond à ton problème.

radama

Tu peux tester ton indicateur R2 directement dans les statistiques sans remettre le code :

Si CROISE(R2.R2,0.27)>0 Alors Selection

En espérant que cela répond à ton problème.

radama


Merci pour ton aide Radama,

Voici la statistique modifiée.

Bonsoir Chctrader.

Merci pour ton R2 qui renseigne très bien sur la force de la tendance de la régression linéaire comme le dit Bertrand Richard dans son article d'Action Future n°12. Celle-ci tient compte du nombre de jours choisis pour calculer la régression. Ok çà marche.

Pour résoudre ton problème du test statistique de franchissement des trigs, je me suis inspiré de l'exemple "Stat Seuils" que MLOG livre avec la V 3.07. Cet exemple est très révélatif des possibilités qu'offrent les Règles Statistiques et mérite qu'on l'étudie de près.
Venons-en aux faits.

Tout d'abord je supprime le programme de calcul du R2 de la règle statistique.
Il est inutile de l'intégrer à la règle puisqu'il existe déjà comme indicateur. Pour faire référence à la valeur du R2 il suffit d'INSERER sa valeur en utilisant la syntaxe "Règle_R2.R2" qui signifie qu'on veut disposer de la valeur de la variable R2 de la règle "Règle_R2".

Ensuite j'ai renommé TRIG1 et TRIG2 les deux niveaux de trigs. Mais cela n'est pas très important.
En l'occurence on garde TRIG1=0.27 et TRIG2=0.79 dans l'exemple avec P1=14 jours comme tu l'indiques.

Voici le programme de la règle statistique (il fonctionne) :

----------------------------------------------
//STATISTIQUE DE FRANCHISSEMENT DES TRIG
//

TRIG1=0.27
TRIG2=0.79

FRANCHISSEMENT = 0
SI TRIG1<>0
ALORS
FRANCHISSEMENT = CROISE(Règle_R2.R2,TRIG1)
NIVEAU = TRIG1
FINSI

SI TRIG2<>0 ET FRANCHISSEMENT=0
ALORS
FRANCHISSEMENT = CROISE(Règle_R2.R2,TRIG2)
NIVEAU = TRIG2
FINSI

SI FRANCHISSEMENT>0
ALORS
COLONNE1 = "TRIG " & NIVEAU & " FRANCHI A LA HAUSSE " & CTXT$(Règle_R2.R2,2)
COLONNE2 = 1
SELECTION
FINSI

SI FRANCHISSEMENT<0
ALORS
COLONNE1 = "TRIG " & NIVEAU & " FRANCHI A LA BAISSE " & CTXT$(Règle_R2.R2,2)
COLONNE2 = -1
SELECTION
FINSI
----------------------------------------------

J'ai conservé les deux types de franchissements possibles des trigs, à la hausse et aussi à la baisse. Cela peut être intéressant de les avoir(?).

Voici la fenêtre Propriétés :



J'utilise comme tu peux le constater la COLONNE2 comme variable de tri des résultats. Elle est évidemment rendue invisible dans le tableau final.


Et voici un exemple sur le CAC40 aujourd'hui :




Une dernière petite chose. Dans ta formule de calcul de R2 du programme de l'indicateur, tu peux écrire directement:
R2 = a^2/(b*c)
ainsi tu évites d'utiliser la fonction RACINE.

Bonne lecture.

Ah je vois que des réponses ont déjà été envoyées...
Excuse-moi...

citation :

---

Citation de smallcaps90

Ah je vois que des réponses ont déjà été envoyées...
Excuse-moi...

---

Ne t'excuses pas, ton approche sérieuse et structurée nous fait entrevoir d'autres possibilités de programmations. La simplifications des équations est précieuse. Merci pour ton aide.

Je vais essayer de m'attaquer à l'erreur type et au Time Séries Forecast, toujours sur la base de la régression linéaire.

Chris

Merci Chctrader.
Je te souhaire bon courage alors...
et bonne nuit...

Trois indicateurs + un système de trading

Bonjour,

Quelqu'un aurait il la possibilité de réaliser le codage en langage GraphAT de ces indicateurs et ce système ? Ce système offre des points de retournements possibles (points pivot).


1 / RSI lissé
EMA1=EMA(RSI(14),7);
EMA2=EMA(EMA1,7);
RSILISS=2*EMA1-EMA2;

EMA pour moyenne mobile exponentielle

2/ StochRSI
(Stochastique RSI)

period = 14;
StochRSI =( ( RSI( period ) - LLV( RSI( period ) , period ) ) / ( ( HHV( RSI(period ) , period ) ) - LLV(RSI( period ), period ) ) );

Graphique=100*StochRSI


3/ Chandle Momentum Oscillator (CMO)

cmopds=14;
CMO_1=Sum( IIf( C > Ref( C, -1 ) , ( C - Ref( C ,-1 ) ) ,0 ) ,cmopds ) ;
CMO_2=Sum( IIf( C < Ref( C ,-1 ) , ( Ref( C ,-1 ) - C ) ,0 ) ,cmopds );
CMO=100 * (( CMO_1 -CMO_2) /( CMO_1+CMO_2));

Le CMO s'affiche sous forme de batons. C'est un indicateur de surachat/survente très efficace. Il faut matérialiser 4 limites :
50
-50
35
-35

Il peut être lissé comme le RSI lissé ci-dessus pour mieux l'appréhender graphiquement.

SYSTEME DE TRADING :

Réalisé à partir de la définition du CMO et du STORSI ci-dessus :

cmopds=14;
CMO_1=Sum( IIf( C > Ref( C, -1 ) , ( C - Ref( C ,-1 ) ) ,0 ) ,cmopds ) ;
CMO_2=Sum( IIf( C < Ref( C ,-1 ) , ( Ref( C ,-1 ) - C ) ,0 ) ,cmopds );

CMO=100 * (( CMO_1 -CMO_2) /( CMO_1+CMO_2));


//StochRSI
period = 14;

StochRSI=( ( RSI( period ) - LLV( RSI( period ) , period ) ) / ( ( HHV( RSI(
period ) , period ) ) - LLV(RSI( period ), period ) ) );

Achat= StochRSI=20 AND CMO<-50 ;
Vente= StochRSI=80 AND CMO>60;

Ce système offre des points de retournements possibles avec beaucoup d'accuité (I love it !). Il faut cependant obligatoirement les valider à l'aide d'une analyse chartiste.

A UTILISER A VOS PROPRES RISQUES.

Et voilà, merci.

Bonjour Pwaget.

Voici ce que çà pourrait donner.

Programme, il comporte 4 règles :

------------------------------------------------------
//1-REGLE RSILISSE

DELTA = CLOTURE-CLOTURE(1)
SI DELTA>0
ALORS
MH = (MH*(P1-1)+DELTA)/P1
MB = (MB*(P1-1))/P1
SINON
MB = (MB*(P1-1)-DELTA)/P1
MH = (MH*(P1-1))/P1
FINSI
RSI_2(0) = 100*(MH/(MH+MB))

M1(0)=EXPOSUIV(M1,RSI_2,P2)
M2(0)=EXPOSUIV(M2,M1,P2)
RSILISSE(0)=2*M1-M2 //DEMA de Patrick Mulloy

//2-REGLE STOCHRSI

L = MIN(RSILISSE.RSI_2,14)
H = MAX(RSILISSE.RSI_2,14)
STOCHRSI(0) = 100*(RSILISSE.RSI_2-L)/(H-L)

//2-REGLE CMO de TUSHAR CHANDLE

CMO_1(0) = SOMME((CLOTURE-CLOTURE(1))*(CLOTURE>CLOTURE(1)),14)
CMO_2(0) = SOMME((CLOTURE(1)-CLOTURE)*(CLOTURE<CLOTURE(1)),14)
CMO(0)=100*(CMO_1-CMO_2)/(CMO_1+CMO_2)

L1(0)=50
L2(0)=-50
L3(0)=35
L4(0)=-35

//2-REGLE D'ACHAT ET DE VENTE

ACHAT(0) =(-1)*( (STOCHRSI.STOCHRSI<20) ET (CMO.CMO<-50))
VENTE(0) = (STOCHRSI.STOCHRSI>80) ET (CMO.CMO>50)
------------------------------------------------------

Propriétés :

Règle RSILISSE :
J'ai inclus le programme du RSI (noté RSI_2) pour ne pas avoir à revenir dans la fenêtre de réglage des paramètres des indicateurs prédéfinis de GrapheAT. Mais ce n'est pas une obligation.
On trace une courbe RSILISSE de type simple, épaisseur 1. Le paramètre P1 est règlé à 14.
On définit aussi une courbe RSI_2, sans la tracer, pour pouvoir récupérer sa valeur dans le STOCHRSI.

Règle STOCHRSI :
Une courbe est définie : STOCHRSI de type simple épaisseur 2. Paramètre P1 = 14.

Règle CMO :
5 courbes à définir : CMO type Histogramme épaisseur 2, L1, L2, L3, L4 de type simple. Je te laisse chosir les couleurs...
Paramètre P1=14.

Règle SYSTEMETRADING :
Deux courbes : ACHAT de type "Flèche bas" et VENTE de type "Flèche haut", Epaisseurs 2.
P1=20, P2=-35, P3=80, P4=35...tu peux en changer les valeurs.

Exemple avec Alcatel :



Cela demanderait à être affiné pour ne laisser subsister qu'une alternance : 1 flèche ACHAT, 1 flèche VENTE, 1 flèche ACHAT, 1 flèche VENTE...

Super tout cela,

j'aimais bien le stochrsi, mais le cmo m'a l'air prometteur également , je vais regarder tout cela sur d'autre config.

A PWAGET:

je ne vois pas à quel niveau intervient le rsi lissé, c'est juste visuel pour valider ?