Bonsoir à tous,

Petit coucou de Barcelone ou je passe qq jours... Malgré les vacances le trading n'est pas oublié. J'en profite pour vous poster une image du DAX avec son Time Series Forecast associé à ses canaux d'erreur type.

// TIME SERIES FORECAST
// associé à ses canaux d'Erreur Type

somx = 0
somy = 0
somxx = 0
somxy = 0
somyy = 0
Pour P1 Cours
somx = somx+RANGPOUR
somy = somy+Cloture
somxx = somxx+RANGPOUR*RANGPOUR
somxy = somxy+RANGPOUR*Cloture
somyy = somyy+Cloture*Cloture
FinPour

a = (P1*somxy-somx*somy)
b = (P1*somxx-somx*somx)
c = (P1*somyy-somy*somy)
d = 1/P1*(P1-2)
z = (P1*somxy-somx*somy)/(P1*somxx-somx*somx)
w = (somy-z*somx)/P1
REGLIN = z*P1+w
TSF = REGLIN+z

ERREURTYPE = racine(d*(c-a^2/b))

ERTUP = TSF+P2*ERREURTYPE/10
ERTDW = TSF-P2*ERREURTYPE/10

Re Bomdu,

Voici ton programme :

---------------------
//Droite "inclinée" de 30° sur l'horizontale, passant par
//le plus bas de la période P1 avant le cours actuel
//et tracée pendant P2 périodes à partir de ce plus bas.
//

PENTE=RACINE(3)/3 //tan(30)

SI RANGHISTO= FINHISTO
ALORS
BS=BAS(P1-1)
POUR P1 COURS
SI RANGPOUR>P2
ALORS
BREAK
FINSI
X(0)=RANGPOUR
Y(0) =PENTE*(X-1)+BS
FINPOUR
FINSI
---------------------

Tu déclares les 2 paramètres P1 et P2 et une courbe Y de type "Segments". Tu coches la case "Affichage sur les cours".

Deux exemples :





Bonne soirée.

Bonsoir,

pour compléter avec les nouvelles possibilités de la version 3.7, ci joint un lien vers un post traitant des moyennes de Guppy sous grapheAT pro.

urlfrm/topic.asp?TOPIC_ID=10729/url


Bruno.

Bonjour,

Pouvez vous me donner la façon de faire (avec une copie d'écran car je suis nul en informatique) pour avoir l'information du passage, à la hausse (noté :achat) et à la baisse (vente) de la moyenne des bollingers en daily (et si possible en Weekly) avec le module statistique de Graph AT pro.

Bonsoir FOKI,

Statistique de passage à la hausse (achat) et à la baisse (vente) de la MBOLL.
Solution possible sachant qu'il pourrait y en avoir d'autres...

Programme à placer dans l'onglet Jour de la règle statistique :

----------------------------
//Statistique de passage de la MBOLL à la hausse et à la baisse
//

ACTIONSELECT=0
NBPERIODES=100

POUR NBPERIODES COURS

SI MBOLL(2)<=MBOLL(1) ET MBOLL(1)>MBOLL(0) //détection d'un sommet
ALORS
ACTIONSELECT=1
COLONNE1="MBOLL PASSE A LA BAISSE LE " & DATEHISTO$ & " VENTE"
FINSI

SI MBOLL(2)>=MBOLL(1) ET MBOLL(1)<MBOLL(0) //détection d'un creux
ALORS
ACTIONSELECT=-1
COLONNE1="MBOLL PASSE A LA HAUSSE LE " & DATEHISTO$ & " ACHAT"
FINSI
FINPOUR

SI ACTIONSELECT=1
ALORS
SELECTION
ACTIONSELECT=0
FINSI

SI ACTIONSELECT=-1
ALORS
SELECTION
ACTIONSELECT=0
FINSI
-----------------------------


Tu peux évidemment changer la valeur du paramètre N à ta guise.

Propriétés :



Résultats avec un groupe d'action choisi pour exemple :



Pour ce qui concerne l'onglet "Semaine" de la règle statistique, il suffit de recopier le même programme que ci-dessus sous cet onglet.

Quand on applique la règle statistique avec les deux programmes on obtient :




Pour visualiser et vérifier quelles sont les périodes où la MBOLL change de sens, j'ai utilisé le programme ci-dessus, légèrement modifié, comme règle indicateur avec "Affichage sur les cours" de flèches bleues en cas de passage de la MBOLL vers le haut, signal d'achat pour toi, de flèches rouges en cas de passage à la baisse de la MBOLL (vente) et avec tracé de la MBOLL.

Programme :

------------------------------
//Sommets de MBOLL
//

M_BOLL=MBOLL

SI MBOLL(2)<=MBOLL(1) ET MBOLL(1)>MBOLL(0) //détection d'un sommet
ALORS
FLECHE_VENTE(1)=1
FINSI

SI MBOLL(2)>=MBOLL(1) ET MBOLL(1)<MBOLL(0) //détection d'un creux
ALORS
FLECHE_ACHAT(1)=-1
FINSI
------------------------------

Propriétés :



Exemples avec Renault en Daily :



et pour le Weekly :



Comme l'indicateur est tracé sur les cours il est normal que les flèches d'achat/vente soient positionnées sur ceux-ci et non pas sur la MBOLL.

Bonne soirée.

Bonsoir Chctrader,

Pour résoudre ton problème, j'ai créé une règle qui comporte deux fois le programme de tracé des canaux de Raff tels qu'il a été posté à la page : frm/topic.asp?TOPIC_ID=&... , avec des paramètres différents : P1 et P2 pour le tracé du canal à 60 périodes puis P3 et P4 pour celui comportant 14 périodes.
Les variables de la première partie ont pour indice 1, celles de la deuxième ont l'indice 2.

Programme :

-----------------------------
//Premier canal de Raff (P1=0 par exemple et P2=60 périodes)
//

SI RANGHISTO = FINHISTO - P1
ALORS

POUR P2 COURS
X1(0) = RANGPOUR
Y1(0) = CLOTURE
FINPOUR

SOMX1 = SOMME(X1,P2)
SOMY1 = SOMME(Y1,P2)
SOMXX1 = SOMME(X1*X1,P2)
SOMXY1 = SOMME(X1*Y1,P2)

A1 = (P2*SOMXY1-SOMX1*SOMY1)/(P2*SOMXX1-SOMX1*SOMX1)
B1 = (SOMY1-A1*SOMX1)/P2

POUR P2 COURS
DROITE1 = A1 * X1 + B1
FINPOUR

ECARTHAUT1 = MAX(HAUT-DROITE1,P2)
EH1 = ECARTHAUT1
ECARTBAS1 = MAX(DROITE1-BAS,P2)
EB1 = ECARTBAS1
ECART1 = MAXVAL(EH1,EB1)

POUR P2 COURS
RAFFSUP1 = DROITE1 + ECART1
RAFFINF1 = DROITE1 - ECART1
FINPOUR

FINSI

//Deuxième canal de Raff (P3=0 par exemple et P4=14 périodes)
//
SI RANGHISTO = FINHISTO - P3
ALORS

POUR P4 COURS
X2(0) = RANGPOUR
Y2(0) = CLOTURE
FINPOUR

SOMX2 = SOMME(X2,P4)
SOMY2 = SOMME(Y2,P4)
SOMXX2 = SOMME(X2*X2,P4)
SOMXY2 = SOMME(X2*Y2,P4)

A2 = (P4*SOMXY2-SOMX2*SOMY2)/(P4*SOMXX2-SOMX2*SOMX2)
B2 = (SOMY2-A2*SOMX2)/P4

POUR P4 COURS
DROITE2 = A2 * X2 + B2
FINPOUR

ECARTHAUT2 = MAX(HAUT-DROITE2,P4)
EH2 = ECARTHAUT2
ECARTBAS2 = MAX(DROITE2-BAS,P4)
EB2 = ECARTBAS2
ECART2 = MAXVAL(EH2,EB2)

POUR P4 COURS
RAFFSUP2 = DROITE2 + ECART2
RAFFINF2 = DROITE2 - ECART2
FINPOUR

FINSI
-----------------------------

Propriétés :



Exemple avec Renault :



Ici j'ai choisi P1 et P3=0. On pourrait prendre des valeurs différentes bien sûr.
Par exemple avec P1=0, P2=60, P3=15 et P4=25 cela donne :




Bon week-end.

Merci Smallcap,

Je viens de prendre connaissance de ton post pour résoudre mon problème. Je vais mettre cela sur Graph AT dans la journée et voir les résultats.

Bon Week et encore merci.

Merci pour ton aide smallcaps,

Cela va me permettre de mieux reperer les "micro-tendances" dans les tendances plus long terme.

Chris

Bonjour Smallcap,

J'ai fait la manip et c'est OK.
J'ai regardé et je suis d'ailleurs surpris de la quantité d'infos même avec un nombre N de 1 (j'ai testé sur le SRD sur la date du 14/05/04 et il y a déjà une vingtaine de titres détectés).

Le problème c'est que la stat regroupe les daily et weekly, sans les diférencier et c'est difficile à traiter car on ne sait pas qui est quoi sauf à aller les visualiser graphiquement.
Serait t'il possible de faire 2 stats séparées (Une stat daily et une autre weekly) ou bien indiquer dans la stat "daily" et "Weekly".

Euh ! si c'est techniquement possible bien sûre.

Thanks

Bonsoir Foki,

Je pense que c'est possible : en coupant (CTRL+X) le programme de la règle statistique dans l'onglet "Semaine", tu dois avoir des résultats pour la période "Jour" seulement.
Si tu recolles ensuite (CTRL+V)le programme sous l'onglet "Semaine" après l'avoir coupé de l'onglet "Jour", tu auras les résultats de la période "Semaine" seuls...

Merci Smallcaps

J'y vais de ce pas.

Bonjour Smallcap

J'ai fait la manip c'est OK (et je ne suis pas très fière de ne pas avoir pensé à cette solution qui est toute simple).

Thanks pour ta précieuse aide.

Bonjour,

Très intéressé par les possibilités de programmation des Statistiques que je mets en oeuvre d'ores et déjà pour mes propres besoins j'aimerais savoir si MLog a l'intention de nous donner accès aux données Intraday issues des flux ABCBourse.
Ce serait une avancée importante.
Quelqu'un sait-il ? Quelqu'un est-il intéressé pour que nous puissions à plusieurs appuyaer une telle demande à MLog ?
D'avance merci.
Cordialement.

citation :

---

Citation de bourgogne

Bonjour,

Très intéressé par les possibilités de programmation des Statistiques que je mets en oeuvre d'ores et déjà pour mes propres besoins j'aimerais savoir si MLog a l'intention de nous donner accès aux données Intraday issues des flux ABCBourse.
Ce serait une avancée importante.
Quelqu'un sait-il ? Quelqu'un est-il intéressé pour que nous puissions à plusieurs appuyaer une telle demande à MLog ?
D'avance merci.
Cordialement.

---

Bonjour,

bonne idée! quelqu'un a-t-il déjà effectué cette requête auprès de Mlog? y-a-t-il des solutions alternatives pour picker les données intraday?


sinon, partant pour appuyer la demande!