Qui pourrait m'aider à coder cet indicateur : %bRSI ?

%bRSI=(RSI-BandeBollingerInf(RSI)) / (BandeBollingerSup(RSI) - BandeBollingerInf(RSI));

Il s'agit d'un indicateur qui se révèle très souvent précurseur par rapport aux autres indicateurs.

Bonjour Pwaget,

Je débarque des Dolomites et avant de repartir pour la Méditerranée je te propose une solution possible à ton pb :

Un premier indicateur reprogramme de RSI et calcule ses "Bollinger's".

----------------------------
//Bollingers's du RSI
//

// 1- R_S_I
//
DELTA= CLOTURE - CLOTURE(1)
SI DELTA>0 ALORS
MH = (MH * (P1-1) + DELTA) / P1
MB = (MB * (P1-1)) / P1
SINON
MB = (MB * (P1-1) - DELTA) / P1
MH = (MH * (P1-1)) / P1
FINSI

R_S_I(0) = 100 * (MH / (MH + MB))


// 2- Bollinger's du R_S_I
//
MOY_BOLL_RSI = MOYENNE(R_S_I,P2)
ECART= ECARTYPE(R_S_I,P2)
BOLL_RSI_SUP = MOY_BOLL_RSI + P3 * ECART
BOLL_RSI_INF = MOY_BOLL_RSI - P3 * ECART
----------------------------

La reprogrammation du RSI n'est pas vraiment indispensable. Elle permet juste de pouvoir le visualiser plus aisément avec ses Bollinger's (courbes R_S_I, MOY_BOLL_RSI, BOLL_RSI_SUP, BOLL_RSI_INF).
Les paramètres :
P1 : durée du calcul du R_S_I,
P2 : durée de calcul de la moyenne des Bollinger's du R_S_I,
P3 : nombre d'écarts-types retenus pour les Bollinger's sup et inf.

Un deuxième indicateur, dérivé du précédent, calcule le BRSI (et permet de le tracer séparément des précédents) :
----------------------------
//3- Indicateur BRSI
//

BRSI=(R_S_I - BOLL_RSI_INF)/(BOLL_RSI_SUP - BOLL_RSI_INF)
----------------------------
On trace une courbe : BRSI.


Cela donne avec les valeurs des paramètres P1=14, P2=14,P3=2 :



Bonne continuation.

Merci Smallcaps ! tu es génial comme d'habitude. Je pense que tout le monde aura compris visuellement l'intérêt de cet indicateur. Bonne continuation de vacances !

Re Pwaget,

Merci tu es gentil mais rien, ni personne, n'est génial en l'occurence.
Je t'ai juste donné un petit coup de main...
Bonne soirée.

Bonjour,

Je cherche à tracer des droites d'Andrews dans GraphAT Pro.
Le tracé manuel est assez simple:
- on choisi 3 points consécutifs représentant des cours extrêmes, +haut et +bas(exemple avec le SOXX plus bas)
- le premier point est le sommet d'un triangle isocèle à partir duquel est tracé la médiane rejoignant la base opposée. ceci constitue la médiane de la fourchette
- les deux parallèles à cette médiane et passant par les deux autres sommets du trinagle finissent de constituer la fourchette



Qui peut m'aider sur cette programmation ?

merci d'avance

Bonjour,

Je rencontre un problème avec Graph AT car je souhaite modifier mon MACD qui est actuellement en 12/26/9 par un 9/19/6. Je suis rentré pour cela dans "Règle" "Indicateur" " Règle MACD" et j'ai décoché "Non modifiable" puis j'ai modifié P1,P2,P3 avec les valeurs 9/19/6 puis je fais quitter mais mes courbes ne sont pas changées sur mon graphique, il reste en 12/26/9 imanquablement malgré toutes mes manips ???

Quelqu'un pourrait t'il m'expliquer le hic??

FOKI

Pendant que j'y suis une nouvelle question

Je voudrais avoir avec Graph AT les cours du blés daily.

est ce possible et comment ??

FOKI

Bonjour FOKI,
Concernant ta premiere question va dans "Options" puis "Indicateurs" et tu trouveras tous les parametres des indicateurs classiques.

C'est fait EDJE, je te remercie.

Bonjour Roque,

Voici une solution possible à ton problème de tracé des "Andrews Pitchfork".

Comme on ne peut pas (pas encore) acquérir un point directement cliqué à la souris sur un graphe, j'ai choisi d'utiliser le dernier segment d'une fonction "zigzag" pour y appuyer la fouche d'Andrews.
Par la même occasion, si on le souhaite, le programme trace aussi cette fonction "zigzag". J'ai utilisé pour ce faire une logique un peu différente, et qui aboutit à un programme un peu plus long que celui qu'avait proposé Rickenbroc dans cette même file page 18.

PROGRAMME :
----------------------------------------------------------------------
//ZIGZAG et ANDREWS PITCHFORK
//

//PARAMETRES :
//
//P1 est la valeur du retracement du zigzag en %
//P2 permet de choisir sur quel élément des cours on souhaite tracer le zigzag
//P2 = 0 zigzag sur les ouvertures
//P2 = 1 zigzag sur les bas
//P2 = 2 zigzag sur les hauts
//P2 = 3 zigzag sur les clôtures
//
//VARIABLES
//
//DONNEE = contient les valeurs des cours suivant la valeur choisie pour P2
//TENDANCE = 1 si zag (historisée)
//TENDANCE = -1 si zig
//MAXI = valeur d'un sommet(non historisée)
//DATEMAXI = date (RANGHISTO) du pic (non historisée)
//MINI = valeur d'un creux (non historisée)
//DATEMINI = date (RANGHISTO) d'un creux (non historisée)
//DELTA = % entre la CLOTURE courante et le MAXI (ou le MINI) actuel (non historisée)
//PENTE_ZAG = pente de chaque segment montant du zigzag (non historisée)
//PENTE_ZIG = pente de chaque segment descendant du zigzag (non historisée)
//ZIG = droite descendante du zigzag, tracée en format SEGMENTS (historisée)
//ZAG = droite montante du zigzag, tracée en format SEGMENTS (historisée)
//MAXI_PRECEDENT = avant-dernier MAXI trouvé (non historisée)
//DATEMAXI_PRECEDENT = sa date (non historisée)
//MINI_PRECEDENT = avant-dernier MINI trouvé (non historisée)
//DATEMINI_PRECEDENT = sa date (non historisée)
//TRACE_ZZ, flag =1 si on termine le zigzag sur un zag , =0 dans le cas contraire(non historisée)
//DATE_MILIEU = RANGHISTO du milieu du zag ou du zig terminal (non historisée)
//ORDONNEE_MILIEU = ordonnée de ce point (non historisée)
//PENTE_FA = pente des segments de la fourche d'Andrews (non historisée)
//Y = ordonnées des points de la ligne médiane de la fourche (historisée)
//YSUP = ordonnées des points de la ligne supérieure de la fourche (historisée)
//YINF = ordonnées des points de la ligne inférieure de la fourche (historisée)
//DERNIER_ZZ = dernier segment du zigzag sur lequel s'appuie la fourche (historisée)

//CARACTERISTIQUES DES COURBES UTILISEES
//
//ZAG type "segments", couleur "bleue", épaisseur "1"
//ZIG type "segments", couleur "bleue", épaisseur "1"
//Y type "segments", couleur "rouge", épaisseur "1"
//YSUP type "segments", couleur "rouge", épaisseur "1"
//YINF type "segments", couleur "rouge", épaisseur "1"
//DERNIER_ZZ type "segments", couleur "rouge", épaisseur "1"


//0- PREPARER LES DONNEES
//
SI P2=0 ALORS DONNEE(0)=OUVERTURE
SI P2=1 ALORS DONNEE=BAS
SI P2=2 ALORS DONNEE=HAUT
SI P2=3 ALORS DONNEE=CLOTURE

//1- TRAITER LE PREMIER COURS/INITIALISER
//
SI RANGHISTO=1 ALORS
TENDANCE(0)=0
MAXI=DONNEE
MINI=DONNEE
DATEMAXI=1
DATEMINI=1
FINSI

//2- ASSURER LA CONTINUITE DE LA TENDANCE
TENDANCE=TENDANCE(1)

//3- DETERMINER LA TENDANCE INITIALE
//
SI TENDANCE=0
ALORS
DELTA=100*(DONNEE-MINI)/MINI
SI DELTA>P1
ALORS
MAXI=DONNEE
DATEMAXI=RANGHISTO
TENDANCE=1
SINON
SI DELTA<-P1
ALORS
MINI=DONNEE
DATEMINI=RANGHISTO
TENDANCE=-1
FINSI
FINSI
FINSI


//4- EXAMINER LA TENDANCE HAUSSIERE
//PASSER EN TENDANCE BAISSIERE SI NECESSAIRE
//TRACER LE ZAG
//
SI TENDANCE=1
ALORS
SI DONNEE>=MAXI
ALORS
MAXI=DONNEE
DATEMAXI=RANGHISTO
SINON
DELTA=100*(DONNEE-MAXI)/MAXI
SI DELTA<-P1
ALORS
TENDANCE=-1
//Tracer le segment montant
PENTE_ZAG=(MAXI-MINI)/(DATEMAXI-DATEMINI)

POUR (RANGHISTO-DATEMINI+1) COURS
ZAG(0)=PENTE_ZAG*(RANGPOUR-1)+MINI
SI RANGPOUR>(DATEMAXI-DATEMINI) ALORS BREAK
FINPOUR

// Autre solution avec TANT QUE si vous préférez
//--------------------------------------------
//I=RANGHISTO-DATEMAXI
//TANTQUE (I<=RANGHISTO-DATEMINI) FAIRE
//ZAG(I)=PENTE_ZAG*(RANGHISTO-DATEMINI-I)+MINI
//I=I+1
//FINTANTQUE
//--------------------------------------------

TRACE_ZZ = 1

//Mettre à jour
MINI_PRECEDENT=MINI
DATEMINI_PRECEDENT=DATEMINI
MINI=DONNEE
DATEMINI=RANGHISTO
FINSI
FINSI
FINSI


//5- EXAMINER LA TENDANCE BAISSIERE
//PASSER EN TENDANCE HAUSSIERE SI NECESSAIRE
//TRACER LE ZIG
//
SI TENDANCE=-1
ALORS
SI DONNEE<=MINI
ALORS
MINI=DONNEE
DATEMINI=RANGHISTO
SINON
DELTA=100*(DONNEE-MINI)/MINI
SI DELTA>P1
ALORS
TENDANCE=1
//Tracer le segment descendant
PENTE_ZIG=(MINI-MAXI)/(DATEMINI-DATEMAXI)

POUR (RANGHISTO-DATEMAXI+1) COURS
ZIG(0)=PENTE_ZIG*(RANGPOUR-1)+MAXI
SI RANGPOUR>(DATEMINI-DATEMAXI) ALORS BREAK
FINPOUR

//Autre solution avec TANTQUE si vous préférez
//--------------------------------------------
//I=RANGHISTO-DATEMINI
//TANTQUE (I<=RANGHISTO-DATEMAXI) FAIRE
//ZIG(I)=PENTE_ZIG*(RANGHISTO-DATEMAXI-I)+MAXI
//I=I+1
//FINTANTQUE
//--------------------------------------------

TRACE_ZZ=0

//Mettre à jour
MAXI_PRECEDENT=MAXI
DATEMAXI_PRECEDENT=DATEMAXI
MAXI=DONNEE
DATEMAXI=RANGHISTO
FINSI
FINSI
FINSI


//6- TRACER LA FOURCHE DE ANDREW SUR LE DERNIER ZAG OU DERNIER ZIG
//
SI RANGHISTO=FINHISTO
ALORS

SI TRACE_ZZ=1 //On termine le zigzag sur un zag
ALORS

POUR (FINHISTO-DATEMINI_PRECEDENT+1) COURS
DERNIER_ZZ(0)=PENTE_ZAG*(RANGPOUR-1)+MINI_PRECEDENT
SI RANGPOUR>(DATEMAXI-DATEMINI_PRECEDENT) ALORS BREAK
FINPOUR

DATE_MILIEU = (DATEMINI_PRECEDENT+DATEMAXI)/2
ORDONNEE_MILIEU = (MINI_PRECEDENT+MAXI)/2
PENTE_FA = (ORDONNEE_MILIEU-MAXI_PRECEDENT)/(DATE_MILIEU-DATEMAXI_PRECEDENT)

POUR (FINHISTO-DATEMAXI_PRECEDENT+1) COURS
Y(0)=PENTE_FA*(RANGPOUR-1)+MAXI_PRECEDENT
FINPOUR

POUR (FINHISTO-DATEMAXI+1) COURS
YSUP(0)=PENTE_FA*(RANGPOUR-1)+MAXI
FINPOUR

POUR (FINHISTO-DATEMINI_PRECEDENT+1) COURS
YINF(0)=PENTE_FA*(RANGPOUR-1)+MINI_PRECEDENT
FINPOUR

SINON //On termine le zigzag sur un zig

POUR (FINHISTO-DATEMAXI_PRECEDENT+1) COURS
DERNIER_ZZ(0)=PENTE_ZIG*(RANGPOUR-1)+MAXI_PRECEDENT
SI RANGPOUR>(DATEMINI-DATEMAXI_PRECEDENT) ALORS BREAK
FINPOUR

DATE_MILIEU = (DATEMAXI_PRECEDENT+DATEMINI)/2
ORDONNEE_MILIEU = (MAXI_PRECEDENT+MINI)/2
PENTE_FA = (ORDONNEE_MILIEU-MINI_PRECEDENT)/(DATE_MILIEU-DATEMINI_PRECEDENT)

POUR (FINHISTO-DATEMINI_PRECEDENT+1) COURS
Y(0)=PENTE_FA*(RANGPOUR-1)+MINI_PRECEDENT
FINPOUR

POUR (FINHISTO-DATEMAXI_PRECEDENT+1) COURS
YSUP(0)=PENTE_FA*(RANGPOUR-1)+MAXI_PRECEDENT
FINPOUR

POUR (FINHISTO-DATEMINI+1) COURS
YINF(0)=PENTE_FA*(RANGPOUR-1)+MINI
FINPOUR

FINSI

FINSI
----------------------------------------------------------------------

Quelques explications sur la programmation :

0- PREPARER LES DONNEES
Suivant la valeur du paramètre P2, le programme affecte à la variable DONNEE les cours d'ouverture, les plus bas, les plus hauts ou les cours de clôture.

1- TRAITER LE PREMIER COURS/INITIALISER
Rien de bien particulier.

2- ASSURER LA CONTINUITE DE LA TENDANCE.
Cette instruction permet de recopier la valeur précédente de la variable TENDANCE afin qu’à chaque période de cotation, il soit possible de connaître la tendance en cours. Celle-ci pouvant bien entendu être modifiée si un changement de tendance intervient à cette période.

3- DETERMINER LA TENDANCE INITIALE
On teste le DELTA (%) entre la DONNEE et le MINI courant par exemple.
On initialise les variables utiles suivant la valeur de DELTA comparée à celle du paramètre P1 de retracement du zigzag.

4- EXAMINER LA TENDANCE HAUSSIERE
On actualise si nécessaire le MAXI et sa DATE.
On vérifie si la tendance s'inverse, auquel cas on trace le segment montant précédent du zigzag (ZAG).
Deux solutions de tracé sont proposées, l'une avec une boucle POUR, l'autre (en commentaires) avec une boucle TANTQUE. A vous de choisir celle qui vous convient.

5- EXAMINER LA TENDANCE BAISSIERE
On actualise si nécessaire le MINI et sa DATE.
Si la tendance s'inverse, on trace le segment descendant précédent du zigzag (ZIG).

6- TRACER LA FOURCHE D'ANDREWS
Suivant que le dernier segment du zigzag est un ZAG ou un ZIG (TRACE_ZZ=1 ou 0), on trace :
- le dernier segment du zigzag (utile pour voir ce dernier segment si on désactive le tracé complet du zigzag),
- la ligne médiane de la fourche après avoir déterminé sa pente et les coordonnées du point milieu du dernier segment du zigzag,
- les lignes supérieure et inférieure de la fourche.

Ne pas oublier de cocher la case "Afficher sur les cours" de la fenêtre "Propriétés".

EXEMPLE DE TRACES POUR LAFARGE (avec un retracement P1 de 2 (%) et P2=3 donc sur les cours de clôture) :

Zigzag seul (désactiver les courbes Y, YSUP, YINF et DERNIER_ZZ):



Andrews pitchfork seule (désactiver les courbes ZAG et ZIG):



Zigzag et Andrews pitchfork (désactiver DERNIER_ZZ seulement) :




Un petit essai et tu me dis si cela te convient...

SALUT A TOUS
juste une petite question
est-il possible de télécharger les cours des indices nasdaq100 sp500 et nasdaq composite sur graphe at pro? si oui, comment, car je n'arrive pas à accéder à l'historique de ces indices.
merci

bonsoir
quelqu'un peut-il me dire s'il est possible de détecter des divergences sur rsi, macd ou histo macd, avec la fonction statistique de graphe at pro?
et si impossible, comment puis-je me débrouiller pour les détecter? y aurait-il une idée de programme sur excel par exemple?
Métastock ou axial finance le peuvent-ils?
merci

Bonjour Talleyrand,

Tu trouveras la réponse à ta question dans la FAQ de l'aide intégrée à GrapheAT Pro au chapître : "Comment utiliser le téléchargement ActionUS ?"

(Désolé, je n'avais pas vu la réponse de FOKI dans l'autre file.)

Bonjour Leo s,

C'est tout à fait envisageable avec les stats de GrapheAT Pro.
Encore faut-il écrire le programme bien sûr.
Il se trouve dans la file d'attente de mes projets depuis un moment. Mais pas en première position...

smallcaps90
je te remercie de ton aide, et de ton aide sur cette file
cordialement