Prévision des plus hauts et des X haussiers (ou baissiers) MACD/SIGNAL.

Voici le programme d'une règle indicateur qui permet de prévoir quels sont les niveaux de Clôture qui, à la prochaine période, pourraient donner un croisement haussier (ou baissier) entre la MACD et son SIGNAL et, à défaut, un simple plus haut sur la MACD sans croisement.

Programme de la règle "PREV_X_MACD" :
--------------------------------------------------
//Prévision du X éventuel MACD/SIGNAL
//V.2.0
//01/03/2005

MECAP1(0) = EXPOSUIV(MECAP1,CLOTURE,P1)
MECAP2(0) = EXPOSUIV(MECAP2,CLOTURE,P2)
MA = MECAP1-MECAP2
SA = EXPOSUIV(SA,MA,P3)

SI RANGHISTO=FINHISTO ALORS
N = 5000
P = 0.25
C =CLOTURE
CFMAXI = (1+P)*C
CFMINI = (1-P)*C
PAS = (CFMAXI-CFMINI)/N
DELTA = -100*P

Afficher NOMACTION$
Afficher DATEHISTO$
afficher ""
Afficher "========="
Afficher "DONNEES"
Afficher "========="
Afficher "CLOTURE actuelle = " & CTXT$(C,2)
Afficher "Borne mini de recherche = " & CTXT$(CFMINI,2)
Afficher "Borne Maxi de recherche = " & CTXT$(CFMAXI,2)
Afficher "MACD actuel = " & CTXT$(MA,6)
Afficher "Signal MACD actuel = " & CTXT$(SA,6)

CF = CFMINI
TANTQUE CF<=CFMAXI FAIRE
DELTA = 100*(CF-C)/C
MECFUTP1 = (2*CF+(P1-1)*MECAP1(0))/(P1+1)
MECFUTP2 = (2*CF+(P2-1)*MECAP2(0))/(P2+1)
MF = MECFUTP1-MECFUTP2
SF = (2*MF+(P3-1)*SA)/(P3+1)

SI MA<SA ET MF>=SF ET XH=0 //X haussier
ALORS
XH = 1
DXH = DELTA
CFXH = CF
MXH = MF
SXH = SF
FINSI

SI MA<SA ET MF>MA ET MF<SF ET H1=0 //simple nouveau + haut sur MACD<SIGNAL sans X
ALORS
H1 = 1
DH1 = DELTA
CFH1 = CF
MH1 = MF
SH1 = SF
FINSI

SI MA>SA ET MF<=SF //X baissier
ALORS
XB = 1
DXB = DELTA
CFXB = CF
MXB = MF
SXB = SF
FINSI

SI MA>SA ET MF>MA ET MF>SF ET H2=0 //simple nouveau + haut sur MACD>SIGNAL
ALORS
H2 = 1
DH2 = DELTA
CFH2 = CF
MH2 = MF
SH2 = SF
FINSI

CF = CF+PAS
FINTANTQUE

Afficher ""
Afficher "==========="
Afficher "RESULTATS"
Afficher "==========="

SI XH=1
ALORS
Afficher "X haussier possible entre la MACD et son SIGNAL"
Afficher "Si % sur CLOTURE >= " & CTXT$(DXH,2) & "%"
Afficher "Nouvelle CLOTURE au X = " & ctxt$(CFXH,2)
Afficher "Nouveaux MACD et SIGNAL = " & CTXT$(MXH,6) & " et " & CTXT$(SXH,6)
FINSI

SI H1=1
ALORS
Afficher ""
Afficher "Simple nouveau + haut possible sur la MACD"
afficher "Dès que % sur CLOTURE >= " & CTXT$(DH1,2) & "%"
Afficher "Nouvelle CLOTURE à ce + haut = " & ctxt$(CFH1,2)
Afficher "Nouveaux MACD et SIGNAL = " & CTXT$(MH1,6) & " et " & CTXT$(SH1,6)
FINSI

SI XB=1
ALORS
Afficher "X baissier possible entre la MACD et son SIGNAL"
Afficher "Si % sur CLOTURE <= " & CTXT$(DXB,2) & "%"
Afficher "Nouvelle CLOTURE au X = " & ctxt$(CFXB,2)
Afficher "Nouveaux MACD et SIGNAL = " & CTXT$(MXB,6) & " et " & CTXT$(SXB,6)
FINSI

SI H2=1
ALORS
Afficher ""
Afficher "Simple nouveau + haut possible sur la MACD"
Afficher "Dès que % sur CLOTURE >= " & CTXT$(DH2,2) & "%"
Afficher "Nouvelle CLOTURE à ce + haut = " & CTXT$(CFH2,2)
Afficher "Nouveaux MACD et SIGNAL = " & CTXT$(MH2,6) & " et " & CTXT$(SH2,6)
FINSI

FINSI
--------------------------------------------------

Le programme est essentiellement organisé autour d'une boucle "TANTQUE" qui effectue, à la dernière période de cotation, la recherche des valeurs qui peuvent éventuellement donner des croisements MACD/SIGNAL et des plus hauts sans croisement sur la MACD.
Cette recherche s'effectue sur 5000 pas de programme (constante N définie en tête de programme).
L'intervalle dans lequel les calculs sont effectués est : 0.75*CLOTURE(0),1.25*CLOTURE(0). Il est possible de modifier cet intervalle par la constante P (P=0.25 ici).
Pour chacune des 5000 valeurs supposées possibles de la prochaine CLOTURE dans cet intervalle, les valeurs correspondantes de la MACD et de son SIGNAL sont calculées et comparées afin de tirer les conclusions qui s'imposent. Celles-ci sont affichées dans la "Fenêtre d'affichage" accessible par le menu "Règles". Il faut évidemment l'ouvrir si vous voulez consulter les résultats sous forme numérique.

Les résultats sont disponibles également sous forme graphique en utilisant la règle indicateur suivante dérivée de la précédente et dont le programme est :

Règle dérivée "NIV_CXMACD" :
------------------------------------------------------------------------------
//Visualisation graphique des prochains niveaux de CLOTURE
//garantissant un + haut, etun X haussier (ou baissier)
//entre la MACD et son SIGNAL
//

SI RANGHISTO=FINHISTO
ALORS
CXH=CFXH
CH1=CFH1
CXB=CFXB
CH2=CFH2
FINSI
------------------------------------------------------------------------------

Fenêtres Propriétés des deux règles :




A titre d'illustration, voici ce que cela donne pour Casino Guichard et Cap Gémini :


Casino Guichard
01/03/2005

=========
DONNEES
=========
CLOTURE actuelle = 62,80
Borne mini de recherche = 47,10
Borne Maxi de recherche = 78,50
MACD actuel = 0,100715
Signal MACD actuel = 0,292851

===========
RESULTATS
===========
X haussier possible entre la MACD et son SIGNAL
Si % sur CLOTURE >= 3,88%
Nouvelle CLOTURE au X = 65,24
Nouveaux MACD et SIGNAL = 0,293058 et 0,292910

Simple nouveau + haut possible sur la MACD
Dès que % sur CLOTURE >= 0,82%
Nouvelle CLOTURE à ce + haut = 63,31
Nouveaux MACD et SIGNAL = 0,100890 et 0,238005

A 17h22 Casino clotûre à 63.05 donc sous les 63.31 qui seraient nécessaires à faire apparaître un plus haut sur la MACD. Il est donc probable que la MACD fera un plus bas ce soir.


Cap Gemini
01/03/2005

=========
DONNEES
=========
CLOTURE actuelle = 28,14
Borne mini de recherche = 21,11
Borne Maxi de recherche = 35,17
MACD actuel = 0,655668
Signal MACD actuel = 0,517406

===========
RESULTATS
===========
X baissier possible entre la MACD et son SIGNAL
Si % sur CLOTURE <= -5,41%
Nouvelle CLOTURE au X = 26,62
Nouveaux MACD et SIGNAL = 0,517323 et 0,517382

Simple nouveau + haut possible sur la MACD
Dès que % sur CLOTURE >= -0,49%
Nouvelle CLOTURE à ce + haut = 28,00
Nouveaux MACD et SIGNAL = 0,655772 et 0,556939

A 17.22 Cap Gémini clotûre à 28.13 donc au dessus des 28.00 requis pour que la MACD fasse un plus haut.
Il n'a aura pas de X baissier évidemment.

On peut utiliser le même principe que présenté ci-dessus pour prévoir d'éventuels croisements entre d'autres indicateurs et leurs signaux et, pourquoi pas, entre deux moyennes mobiles.

PS : ce travail est inspiré d'une idée de Dimitris Tsokakis présentée sur le forum EliteTrader.

Bonjour Smallcaps

Je viens de prendre connaissance de ton nouveau prog .
Je vais mettre tout ça sur Graph AT pour observer.

Dans le même ordre d'idée, tu parles des Moyennes mobiles et pour ma part c'est un élément que je tiens particulièrement compte notamment : M7 et M23.

Il n'est d'ailleurs pas rare de voir sur certains graphs ADT.. (je ne citerai pas de noms) des flèches sur l'orientation probable de ces Moyennes et notamment pour prévoir un croisement ou non croisement ...

Il est relativement simple de voir graphiquement la future évolution probable de ces moyennes en regardant les 7 (ou 23) dernières bougies mais pour le Macd ... chapeau.

Je suis preneur pour le même prog avec les MM.

J'en reviens au prog de détection des différentes divergences que j'utilise tous les soir. Ben depuis quelques temps il y a de nombreuses divergences baissières sur pas mal d'indicateurs, dès la moindre baisse (formation d'une bosse sur l'indicateur et donc détection d'une divergence) mais elle ne se concrétise pas, c'est hallucinant, le marché est haussier contre vent et marée ... wait and see.

FOKI.

Bonsoir Foki,

Tu étais intéressé par le programme de prévision du X des moyennes mobiles, le voici :

--------------------------------------------------------------------------------
//Prévision du X éventuel de 2 moyennes mobiles arithmétiques
//V1.0
//03/03/2005

M1=MOYENNE(CLOTURE,P1)
M2=MOYENNE(CLOTURE,P2)

SI RANGHISTO=FINHISTO ALORS
N = 5000
P = 0.25
C = CLOTURE
CFMAXI = (1+P)*C
CFMINI = (1-P)*C
PAS = (CFMAXI-CFMINI)/N
DELTA = -100*P

Afficher NOMACTION$
Afficher DATEHISTO$
afficher ""
Afficher "========"
Afficher "DONNEES"
Afficher "========"
Afficher "CLOTURE actuelle = " & CTXT$(C,6)
Afficher "Borne mini de recherche = " & CTXT$(CFMINI,6)
Afficher "Borne Maxi de recherche = " & CTXT$(CFMAXI,6)
Afficher "MOYENNE courte actuelle M1 = " & CTXT$(M1,6)
Afficher "MOYENNE longue actuelle M2 = " & CTXT$(M2,6)

CF(0) = CFMINI
TANTQUE CF<=CFMAXI FAIRE
DELTA = 100*(CF-C)/C
M1F = M1+(CF-CLOTURE(P1))/P1
M2F = M2+(CF-CLOTURE(P2))/P2

SI M1<M2 ET M1F>=M2F ET XH=0 //X haussier
ALORS
XH = 1
DXH = DELTA
CFXH = CF
M1XH = M1F
M2XH = M2F
FINSI

SI M1<M2 ET M1F>M1 ET M1F<M2F ET H1=0 //simple nouveau + haut sur moyenne courte sans X
ALORS
H1 = 1
DH1 = DELTA
CFH1 = CF
M1H1 = M1F
M2H1 = M2F
FINSI

SI M1>M2 ET M1F<=M2F //ET XB=0 //X baissier
ALORS
XB = 1
DXB = DELTA
CFXB = CF
M1XB = M1F
M2XB = M2F
FINSI

SI M1>M2 ET M1F>M1 ET M1F>M2F ET H2=0 //simple nouveau + haut sur moyenne courte
ALORS
H2 = 1
DH2 = DELTA
CFH2 = CF
M1H2 = M1F
M2H2 = M2F
FINSI

CF = CF+PAS
FINTANTQUE

Afficher ""
Afficher "=========="
Afficher "RESULTATS"
Afficher "=========="

SI XH=1
ALORS
Afficher "X haussier possible de la moyenne longue par la moyenne courte"
Afficher "Si % sur CLOTURE >= " & CTXT$(DXH,6) & "%"
Afficher "Nouvelle CLOTURE = " & ctxt$(CFXH,6)
Afficher "Nouvelles MOYENNES M1 et M2 = " & CTXT$(M1XH,6) & " et " & CTXT$(M2XH,6)
FINSI

SI H1=1
ALORS
Afficher ""
Afficher "Nouveau + haut possible sur la moyenne courte (sans croisement)"
afficher "Dès que % sur CLOTURE >= " & CTXT$(DH1,6) & "%"
Afficher "Nouvelle CLOTURE à ce + haut = " & ctxt$(CFH1,6)
Afficher "Nouvelles MOYENNES M1 et M2 = " & CTXT$(M1H1,6) & " et " & CTXT$(M2H1,6)
FINSI

SI XB=1
ALORS
Afficher "X baissier possible de la moyenne longue par la moyenne courte"
Afficher "Si % sur CLOTURE <= " & CTXT$(DXB,6) & "%"
Afficher "Nouvelle CLOTURE = " & ctxt$(CFXB,6)
Afficher "Nouvelles MOYENNES M1 et M2 = " & CTXT$(M1XB,6) & " et " & CTXT$(M2XB,6)
FINSI

SI H2=1
ALORS
Afficher ""
Afficher "Nouveau + haut possible sur la moyenne courte (sans croisement)"
Afficher "Dès que % sur CLOTURE >= " & CTXT$(DH2,6) & "%"
Afficher "Nouvelle CLOTURE à ce + haut = " & CTXT$(CFH2,6)
Afficher "Nouvelles MOYENNES M1 et M2 = " & CTXT$(M1H2,6) & " et " & CTXT$(M2H2,6)
FINSI

FINSI
--------------------------------------------------------------------------------
Attention, ce programme ne devine rien. Il se contente de déterminer pour quel niveau futur de la clotûre un croisement peut apparaître entre les deux moyennes. La recherche s'effectue dans un domaine de clotûres défini par la constante P que l'on peut modifier à volonté.
Il est indiqué aussi pour quel niveau de la clotûre future la moyenne courte fera éventuellement un plus haut dans ce domaine.

Fenêtre "Propriétés" :


L'indicateur est tracé sur les cours cette fois.

Quelques exemples au 02/03/05 :

Accor
02/03/2005

=========
DONNEES
=========
CLOTURE actuelle = 35,830000
Borne mini de recherche = 26,872500
Borne Maxi de recherche = 44,787500
MOYENNE courte actuelle M1 = 35,451429
MOYENNE longue actuelle M2 = 35,011739

===========
RESULTATS
===========
X baissier possible de la moyenne longue par la moyenne courte
Si % sur CLOTURE <= -10,990000%
Nouvelle CLOTURE = 31,892283
Nouvelles MOYENNES M1 et M2 = 34,956040 et 34,956186

Nouveau + haut possible sur la moyenne courte (sans croisement)
Dès que % sur CLOTURE >= -1,310000%
Nouvelle CLOTURE à ce + haut = 35,360627
Nouvelles MOYENNES M1 et M2 = 35,451518 et 35,106984

Ici le niveau de clotûre qu'imposerait un croisement baissier de M2 par M1 paraît trop faible pour être atteint. Par contre, si la tendance en cours se maintient, il ya des chances pour qu' Accor fasse un plus nouveau plus haut sur M1.


AGF
02/03/2005

=========
DONNEES
=========
CLOTURE actuelle = 57,900000
Borne mini de recherche = 43,425000
Borne Maxi de recherche = 72,375000
MOYENNE courte actuelle M1 = 57,885714
MOYENNE longue actuelle M2 = 58,008696

===========
RESULTATS
===========
X haussier possible de la moyenne longue par la moyenne courte
Si % sur CLOTURE >= 4,000000%
Nouvelle CLOTURE = 60,216000
Nouvelles MOYENNES M1 et M2 = 58,138000 et 58,137652

Nouveau + haut possible sur la moyenne courte (sans croisement)
Dès que % sur CLOTURE >= 0,950000%
Nouvelle CLOTURE à ce + haut = 58,450050
Nouvelles MOYENNES M1 et M2 = 57,885721 et 58,060872

Pour AGF, le niveau de clotûre qu'il faudrait atteindre ce soir pour avoir un croisement haussier de M2 par M1 semble inaccessible.
Si la clotûre atteint 58.45, M1 fera un nouveau plus haut sinon M1 fera un nouveau plus bas.


Danone
02/03/2005

=======
DONNEES
=======
CLOTURE actuelle = 76,300000
Borne mini de recherche = 57,225000
Borne Maxi de recherche = 95,375000
MOYENNE courte actuelle M1 = 74,928571
MOYENNE longue actuelle M2 = 72,943478

========
RESULTATS
========
Nouveau + haut possible sur la moyenne courte (sans croisement)
Dès que % sur CLOTURE >= -2,750000%
Nouvelle CLOTURE à ce + haut = 74,201750
Nouvelles MOYENNES M1 et M2 = 74,928821 et 73,121815

Pour ce qui concerne Danone, dans le domaine étudié (de -25% à +25% de la clotûre d'hier), il n'y a aucune chance de voir apparaître un croisement baissier de M2 par M1.
Par contre le niveau de clotûre permettant d'obtenir un nouveau plus haut : 74.20, était largement dépassé hier. Il ya donc des chances pour que la moyenne courte M1 fasse un nouveau plus haut ce soir.

Merci Smallcaps

Je viens de prendre connaissance de ton prog sur les MM.

Tu dégaines plus vite que ton ombre ...

Thanks

FOKI

Bonjour,

Novice dans l'utilisation du TS de grapheAT Pro, je recherche un exemple permettant de parametrer la fenetre de test (jour J0 à J1) d'un Trading System,de pouvoir entrer en vente (1=achat, 0=solder,-1=VAD), d'avoir une synthèse sur l'action testée (courbe de gain, max perte/gain, ect ..), d'ajouter les coûts de transation/ordre et de pouvoir le tester dans l'onglet statistique sur plusieurs actions.

Quelqu'un aurait-il déjà écrit ces règles dans graphat pro ? (l'exemple de mlog n'en permet qu'une partie...)

Merci de votre aide.

Bonjour,

y aura-t-il dans la presente file la programmation de l'indicateur TRIX ?

Si oui, merci de m'indiquer la page.

Je n'en sais rien Bomdu,par contre lorsque tu vas dans les indicateurs qui sont déjà préprogrammés dans le dossier classique de GrapheAt Pro,tu prux voir le Trix.

Soit,
// TRIX
ema1 = EXPOSUIV(ema1,Cloture,P1)
ema2 = EXPOSUIV(ema2,ema1,P1)
ema3(0) = EXPOSUIV(ema3,ema2,P1)
RTRIX = 100*(ema3-ema3(1))/ema3(1)

// Moyenne exponentielle du TRIX
RMTRIX = EXPOSUIV(RMTRIX,RTRIX,P2)

Merci providence,

On me l'avait dèja signalé par mail.

bonjour pierdi,

si tu envois ce msg pendant que je suis en CA, je ne peux pas le voir

je poste ça ce WE si je peux.

jlr

citation :

---

Citation de pierdi75

Citation de jlr

j'essaie d'écrire une régle stat pour trier les actions dont les 6 dernières ouvertures et clotures ont eu lieu entre les bandes de Bollinger, avec une volatilité faible

tu pourrais donner la version définitive de ce programme ?

merci !

P

---

Bonjour a tous,

Tout d'abord un petit bonjour à Smallcap qui a été très actif ces temps ci. Merci smallcap pour ton programme des trois lignes car j'y pensais depuis quelques temps et cela m'a évité de le coder. Bon une modeste contribution, mais comme je crois que tu aimes bien les filtres auto-adaptatif on ne sait jamais...

Ce programme s'inspire d'un article récent de John Elhers. Le but est de trouver à chaque jour, la moyenne qui correspond à la médiane, c'est à dire la moyenne qui réparti de manière homogène l'échantillon. Le code que je vous propose là est une adaptation du easy code fourni avec l'article de John Elher+ ma participation très bourrine pour le code de la médiane==>c'est salement cochon mais le easy code est en anglais et le reste est en français... A noter que le calcul de la mediane manque à Graphat. Comme c'est codé à la va que je te pousse j'ai mis un paramétre pour commencer les calculs avec un horizon de 400 jours. A utiliser en complément d'autre indicateur de la moyenne.

Voici le code:

//Median Average Adaptative Filter de John Ehlers



price(0)=(haut+bas)/2
Treshold=P1

Smooth(0)=(price+2*price(1)+2*price(2)+price(3))/6

cpt3=cpt3+1
Si (cpt3>FINHISTO-P2) Alors
lenght=39
value3=0.2
TantQue Value3> Treshold Faire
alpha=2/(lenght+1)

//PP1 est le nombre de jour de calcul de la mediane
PP1=lenght
//calcul la cpt_mediane qui est à la moitié
cpt_mediane=(PP1+1)/2
cpt2=0

TantQue cpt2<PP1 Faire
med=Smooth(cpt2)
cpt2=cpt2+1
cpt=0
cpt1=0

Tantque cpt1<PP1 Faire

Si med>=Smooth(cpt1) Alors
cpt=cpt+1
FinSi
cpt1=cpt1+1

FinTantQue

Si cpt=cpt_mediane alors
Break
FinSi

FinTantQue

Value1(0)=med
Value2(0)=alpha*Smooth+(1-alpha)*value2(1)

Si Value1<>0 Alors Value3=Absolu(Value1-Value2)/Value1 FinSi
lenght=lenght-2
FinTantQue

Si lenght<3 Alors lenght=3 FinSi
alpha=2/(lenght+1)

Filt=alpha*smooth+(1-alpha)*Filt(1)


FinSi

Dans les propriété j'ai mis
INDICATEUR=MAAF
P1=0.002 // c'est la précision pour le calcul de la moyenne
P2=400 //date ou on commence les calculs

1 courbe avec la case affichage sur les cours coché

NOM de la courbe: Filt

Voila, bonne soirée ;-D
Chiffonade sans n

Merci Chiffonade pour cette mise à dispo du nouvel indicateur de J. Ehlers toujours aussi prolixe.
Un petit graphe stp pour illustrer l'intérêt de ce type de moyenne par rapport à ce qu'on connaît déjà...

pierdi,
voilà (enfin !!) le code pour détecter les actions dont les cours des 6 derniers jours sont entre les BB et une volatilité proche (20% dans ce cas) de la volatilité min :

Colonne1 = (UBOLL(0)-LBOLL(0))/MBOLL(0)*100
Colonne2 = CTXT$(Colonne1,2) & "%"

indice = (INDEX_VOLAT.VOLATILITE(0)-INDEX_VOLAT.VOLMIN(0)) /
(INDEX_VOLAT.VOLMAX(0)-INDEX_VOLAT.VOLMIN(0))
limite = 0.2

Si CROISE(MACD,MMACD)>0
et cloture(1) > RSAR.RLBOLL(1) et cloture(2) > RSAR.RLBOLL(2)
et cloture(3) > RSAR.RLBOLL(3) et cloture(4) > RSAR.RLBOLL(4)
et cloture(5) > RSAR.RLBOLL(5) et cloture(6) > RSAR.RLBOLL(6)
et ouverture(1) < RSAR.RUBOLL(1) et ouverture(2) < RSAR.RUBOLL(2)
et ouverture(3) < RSAR.RUBOLL(3) et ouverture(4) < RSAR.RUBOLL(4)
et ouverture(5) < RSAR.RUBOLL(5) et ouverture(6) < RSAR.RUBOLL(6)

et indice < limite
Alors SelectionAchat

citation :

---

Citation de jlr

bonjour pierdi,

si tu envois ce msg pendant que je suis en CA, je ne peux pas le voir

je poste ça ce WE si je peux.

jlr

citation :

---

Citation de pierdi75

Citation de jlr

j'essaie d'écrire une régle stat pour trier les actions dont les 6 dernières ouvertures et clotures ont eu lieu entre les bandes de Bollinger, avec une volatilité faible

tu pourrais donner la version définitive de ce programme ?

merci !

P

---

---

Bonjour,

Sans vouloir être casse noisettes, y aurait il une âme charitable pour détailler le programme ci dessus, un peu comme le fait souvent smallcaps. J'ai pas fait le lien avec le début du programme de JLR et smallcaps.
Merci d'avance c'est sympa

Bonjour Smallcaps.
Sais-tu comment créer des enveloppes autour d'une courbe LOWESS?Je n'arrive à obtenir que le dernier jour,le reste de l'enveloppe s'écrasant sur le bas de l'écran autour de zéro.

Bonjour Providence,

Pas de pb c'est tout à fait possible.
Vu la complexité du programme de régression non paramétrique de type LOWESS que j'avais posté en septembre 2004, je pense qu'il est plus simple d'intervenir en fin de celui-ci.

Donc, si après le dernier FINSI, je colle :

-----------------------
//Tracé d'une enveloppe autour d'une régression LOWESS

SI RANGHISTO=FINHISTO-P1
ALORS

POUR P2 COURS

TR(0) = MAXVAL(ABSOLU(Haut-Bas),ABSOLU(Haut-Cloture(1)))
TR = MAXVAL(TR,ABSOLU(Bas-Cloture(1)))
ATR= Moyenne(TR,20)
LOWESS1=LOWESS+0.5*ATR //courbe sup du canal
LOWESS2=LOWESS-0.5*ATR //courbe inf
FINPOUR

FINSI
-----------------------
.....ainsi on explore les P2 derniers cours sur lesquels la régression est tracée et on calcule les critères qui définissent l'enveloppe souhaitée.
Ici, pour m'appuyer sur un exemple, j'ai choisi de calculer l'Average True Range sur 20 jours et le canal autour de LOWESS est défini à + et - 0.5*ATR.

Pour Thomson voici ce que cela donnerait :


Tu peux bien entendu choisir tout autre façon de définir ce canal.

Pour ce qui concerne ta courbe "écrasée", hormis la façon que tu avais de la calculer, si tu ne veux pas être ennuyé avec une courbe de valeur nulle, affecte le type "Segment" de tracé dans la fenêtre "Propriétés" de la règle aux 2 courbes LOWESS1 et LOWESS2 du canal.

Cordialement.