Bonsoir Fred,


Excuse le retard mis à te répondre, j'ai prolongé un peu mon séjour "helvétique"...

Pour ce qui concerne les cours, je ne peux pas te répondre car je passe par la commande "Importation des cours" que je vais chercher sur abcbourse et je n'ai jamais eu aucun pb pour le faire.

J'ai programmé le "Short-Term Volume and Price Oscillator Price Only" présenté dans TASC de fev. 2008 par Sylvain Vervoort mais pas encore adapté mes prog. sur les divergences régulières et cachées avec cet indicateur. Je le ferai sous peu si tu es intéressé.

//=====
//SVAPO
//=====

//Short-Term Volume and Price Oscillator Price Only
//d'après Sylvain Vervoort (TASC fev 2008)
//smallcaps90
//le 15/03/2008


//TotalPrice
//
ap(0)=(Ouverture+Haut+Bas+Cloture)/4

//Lissage de Vervoort type Heiken Ashi
//
hao(0)=(ap(1)+hao(1))/2
hacl=(ap+hao+Maxval(Haut,MaxVal(ap,hao))+MinVal(Bas,MinVal(ap,hao)))/4

//Lissage TEMA
//
P11=P1/1.6
ME1=Exposuiv(ME1,hacl,P11)
ME2=Exposuiv(ME2,ME1,P11)
ME3=Exposuiv(ME3,ME2,P11)
hac(0)=3*ME1-3*ME2+ME3

//Moyenne moyen terme
//
vave=Moyenne(Cloture(1),5*P1)

//Trend de base
//
//Pente de la régression linéaire des clotures
//
somx = 0
somy = 0
somxx = 0
somxy = 0
somx2 = 0
somy2 = 0
somxx2 = 0
somxy2 = 0
Pour P1 Cours
somx = somx+RANGPOUR
somy = somy+Cloture
somxx = somxx+RANGPOUR*RANGPOUR
somxy = somxy+RANGPOUR*Cloture
FinPour
pente = (P1*somxy-somx*somy)/(P1*somxx-somx*somx)

//Lissage TEMA
//
ME4=Exposuiv(ME4,pente,P1)
ME5=Exposuiv(ME5,ME4,P1)
ME6=Exposuiv(ME6,ME5,P1)
vtrend(0)=3*ME4-3*ME5+ME6

//6 SAVPO
//
cutmul=0.0001*P2
c3(0)=(vtrend>vtrend(1)) OU (vtrend(1)>vtrend(2))
c4(0)=(vtrend>=vtrend(1)) OU (vtrend(1)>=vtrend(2))
c1(0)=(hac>hac(1)*(1+cutmul) ET c4)
c2(0)=(hac<hac(1)*(1-cutmul) ET c3)

som=0
i=0
TantQue i<=P1-1 Faire
Si c1(i)
Alors
som=som+cloture(i)
Sinon
Si c2(i)
Alors
som=som-cloture(i)
FinSi
FinSi
i=i+1
FinTantQue

svap=som/(vave+1)

//Lissage TEMA
//
ME7=Exposuiv(ME7,svap,P1)
ME8=Exposuiv(ME8,ME7,P1)
ME9=Exposuiv(ME9,ME8,P1)
svapo=3*ME7-3*ME8+ME9

//Canal
//
ht=P3*Ecartype(svapo,P5)
bs=-P4*Ecartype(svapo,P5)

//fin du code

Propriétés :



Exemple avec le CAC40 ce soir :





PS1 : j'ai les pdf des 3 articles TASC de S. Vervoort sur ce sujet si cela t'intéresse...

PS2 : le concert de James Blunt au Zénith de Strasbourg vendredi dernier était tout simplement génial!

Cordialement.

Bonjour et merci pour tes réponses smallcaps

Pour ce qui est de l'importation des cours je vais essayer de passer par ABC bourse comme tu le fais.

Je te remercie pour le programme SVAPO.J'ai remarqué qu'il donnait d'assez bonnes divergences.

J'ai réussi à programmé le SVAPO pour les divergences cachées (pour ceux à qui ça interresse). Ca t'éviteras de faire un post Smallcaps .

Voici le code pour les divergences cachées positives entre le SVAPO et les cours:

//===========
//DCP_SVAPO
//===========

//Rechercher la divergence cachée éventuelle la plus récente
//entre les cours et le SVAPO
//V 1.0 du 08/02/2006
//

//-----------------------------------------------------------
//PARAMETRES P1 à P5 :
//
//La divergence potentielle devra se trouver
//P4 périodes avant la FINHISTO.
//
//Le 1er creux (ou le 1er sommet) sur l'indicateur
//devra se trouver dans les P1 périodes qui précèdent
//FINHISTO-P4.
//
//Le 2ème creux (ou le 2ème sommet) sur les cours devra
//se trouver dans les P2 périodes qui précèdent le 1er
//
//Chaque creux (ou sommet) sur les cours devra se trouver
//dans les P3 périodes précédant les creux (ou les sommets)
//sur l'indicateur
//
//P5=0 permet d'accepter les divergences cachées dont
//les segments présentent des intersections avec les
//cours et/ou l'indicateur
//P5=1 ne les accepte pas
//
//PARAMETRES A DEFINIR EN TÊTE DE PROGRAMME
//
//CHOIX_INDIC=1----->SVAPO
//
//TYPE_DIV=1----->Divergence cachée en tendance haussière
//TYPE_DIV=2----->Divergence cachée en tendance baissière
//-----------------------------------------------------------

//Initialisations
//
CHOIX_INDIC=1
TYPE_DIV=1

IND(0)=SVAPO.SVAPO*(CHOIX_INDIC=1)
LIGNE1=SVAPO.HT
LIGNE2=SVAPO.BS


MINI=10000
MAXI=0

//Rechercher la divergence cachée éventuelle
//avant les P4 périodes qui pécèdent la FINHISTO
//
SI RANGHISTO=FINHISTO-P4 ALORS

//Rechercher un 1er creux (ou un 1er sommet) EI1
//sur l'indicateur et sa date DATE_EI1
//
I=0
EI1=MINI*(TYPE_DIV=1)+MAXI*(TYPE_DIV=2)
TANTQUE I<=P1 FAIRE
SI (IND(I+2)>IND(I+1) ET IND(I+1)<IND(I))*(TYPE_DIV=1)
OU (IND(I+2)<IND(I+1) ET IND(I+1)>IND(I))*(TYPE_DIV=2) ALORS
SI (IND(I+1)<=EI1)*(TYPE_DIV=1) OU (IND(I+1)>=EI1)*(TYPE_DIV=2) ALORS
EI1=IND(I+1)
DATE_EI1=FINHISTO-P4-(I+1)
D1=I+1
FINSI
FINSI
I=I+1
FINTANTQUE

SI D1=0 ALORS
AFFICHER "======PAS DE 1ER CREUX RECENT SUR L'INDICATEUR======="
AFFICHER "===============MODIFIEZ P1 ET/OU P4 ================="
STOP
FINSI

//Rechercher le 1er creux (ou le 1er sommet) correspondant EC1
//sur les cours et sa date DATE_EC1
//
EC1=BAS(FINHISTO-P4-DATE_EI1)*(TYPE_DIV=1)
+HAUT(FINHISTO-P4-DATE_EI1)*(TYPE_DIV=2)
DATE_EC1=DATE_EI1
K=FINHISTO-P4-DATE_EI1+1
TANTQUE K<=FINHISTO-P4-DATE_EI1+P3 FAIRE
SI (BAS(K)<=EC1)*(TYPE_DIV=1) OU (HAUT(K)>=EC1)*(TYPE_DIV=2) ALORS
EC1=(BAS(K))*(TYPE_DIV=1)+(HAUT(K))*(TYPE_DIV=2)
DATE_EC1=FINHISTO-K-P4
FINSI
K=K+1
FINTANTQUE

//Rechercher un 2ème creux (ou un 2ème sommet) EI2
//sur l'indicateur et sa date DATE_EI2
//
I=D1+1
EI2=EI1
TANTQUE I<=P2+D1 FAIRE
SI (IND(I+2)>IND(I+1) ET IND(I+1)<IND(I))*(TYPE_DIV=1)
OU (IND(I+2)<IND(I+1) ET IND(I+1)>IND(I))*(TYPE_DIV=2) ALORS
SI (IND(I+1)>=EI1)*(TYPE_DIV=1) OU (IND(I+1)<=EI1)*(TYPE_DIV=2) ALORS
EI2=IND(I+1)
DATE_EI2=FINHISTO-P4-(I+1)
D2=1
FINSI
FINSI

SI D2=1 //On a trouvé un creux (un sommet) EI2 possible
ALORS

SI P5=1 ALORS //La droite EI1--EI2 ne doit pas intersecter l'indicateur
PENTE_I=(EI1-EI2)/(DATE_EI1-DATE_EI2)
POUR (FINHISTO-P4-DATE_EI2+1) COURS
POINT_I(0)= PENTE_I*(RANGPOUR-1)+EI2
SI (POINT_I>IND)*(TYPE_DIV=1) OU (POINT_I<IND)*(TYPE_DIV=2) ALORS
N=1
BREAK
FINSI
SI RANGPOUR>(DATE_EI1-DATE_EI2) ALORS BREAK
FINPOUR
FINSI

SI N=0 ALORS //Droite de divergence correcte sur l'indicateur
//Rechercher le 2ème creux (ou le 2ème sommet) correspondant EC2
//sur les cours et sa date DATE_EC2
//
EC2=(BAS(FINHISTO-P4-DATE_EI2))*(TYPE_DIV=1)
+(HAUT(FINHISTO-P4-DATE_EI2))*(TYPE_DIV=2)
DATE_EC2=DATE_EI2
K=FINHISTO-P4-DATE_EI2+1
TANTQUE K<FINHISTO-P4-DATE_EI2+P3 FAIRE
SI (BAS(K)<=EC2)*(TYPE_DIV=1) OU (HAUT(K)>=EC2)*(TYPE_DIV=2) ALORS
EC2=BAS(K)*(TYPE_DIV=1)+HAUT(K)*(TYPE_DIV=2)
DATE_EC2=FINHISTO-K-P4
FINSI
K=K+1
FINTANTQUE

SI (EC2<=EC1)*(TYPE_DIV=1) OU (EC2>=EC1)*(TYPE_DIV=2) ALORS
SI P5=1 ALORS //La droite EC1--EC2 ne doit pas intersecter les cours
PENTE_C=(EC1-EC2)/(DATE_EC1-DATE_EC2)
POUR (FINHISTO-P4-DATE_EC2+1) COURS
POINT_C(0)=PENTE_C*(RANGPOUR-1)+EC2
SI (POINT_C>BAS)*(TYPE_DIV=1) OU (POINT_C<HAUT)*(TYPE_DIV=2) ALORS
M=1
BREAK
FINSI
SI RANGPOUR>(DATE_EC1-DATE_EC2) ALORS BREAK
FINPOUR
FINSI
SI M=0 ALORS //Droite correcte sur les cours
I=P2+D1+1
SINON
D2=0
FINSI
SINON
D2=0
FINSI
SINON
D2=0
FINSI
FINSI
N=0
M=0
I=I+1
FINTANTQUE

SI D1<>0 ET D2=0 OU EC2=0
ALORS
AFFICHER "============PAS DE DIVERGENCE POTENTIELLE============="
AFFICHER "======AVEC LES VALEURS ACTUELLES DES PARAMETRES======="
AFFICHER "===MAIS IL Y A UN 1ER CREUX SUR L'INDIC ET LES COURS=="
AFFICHER "==============MODIFIEZ EVENTUELLEMENT P2=============="
STOP
FINSI


//Déterminer les points des segments de la divergence
//cachée potentielle sur l'indicateur et les cours
//
SI DATE_EC1-DATE_EC2<5 ALORS //La valeur 5 peut être modifiée
AFFICHER "=============DIVERGENCE POTENTIELLE============"
AFFICHER "==========TROP PETITE POUR ETRE TRACEE========="
AFFICHER "===========MODIFIEZ EVENTUELLEMENT P4=========="
SINON
PENTE_I=(EI1-EI2)/(DATE_EI1-DATE_EI2)
POUR (FINHISTO-P4-DATE_EI2+1) COURS
SEG_I(0)=PENTE_I*(RANGPOUR-1)+EI2
SI RANGPOUR>(DATE_EI1-DATE_EI2) ALORS BREAK
FINPOUR

PENTE_C=(EC1-EC2)/(DATE_EC1-DATE_EC2)
POUR (FINHISTO-P4-DATE_EC2+1) COURS
SEG_C(0)=PENTE_C*(RANGPOUR-1)+EC2
SI RANGPOUR>(DATE_EC1-DATE_EC2) ALORS BREAK
FINPOUR
FINSI

FINSI


Et la fenêtre propriétés:



Voici le programme de divergences cachées sur cours (indicateur dérivé):


//=================
//DCPC_SVAPO
//=================

//V1.0 du 08/02/2006
//

//Tracer le segment de la divergence cachée sur les cours
//

SEG_COURS=SEG_C


Et la fenêtre propriétés:




Voici un exemple de divergences cachées positive entre le SVAPO et les cours:




Maintenant passons au programme de divergences cachées négatives entre le SVAPO et les cours.

Voici le programme:


//===========
//DCN_SVAPO
//===========

//Rechercher la divergence cachée éventuelle la plus récente
//entre les cours et le SVAPO
//V 1.0 du 08/02/2006
//

//-----------------------------------------------------------
//PARAMETRES P1 à P5 :
//
//La divergence potentielle devra se trouver
//P4 périodes avant la FINHISTO.
//
//Le 1er creux (ou le 1er sommet) sur l'indicateur
//devra se trouver dans les P1 périodes qui précèdent
//FINHISTO-P4.
//
//Le 2ème creux (ou le 2ème sommet) sur les cours devra
//se trouver dans les P2 périodes qui précèdent le 1er
//
//Chaque creux (ou sommet) sur les cours devra se trouver
//dans les P3 périodes précédant les creux (ou les sommets)
//sur l'indicateur
//
//P5=0 permet d'accepter les divergences cachées dont
//les segments présentent des intersections avec les
//cours et/ou l'indicateur
//P5=1 ne les accepte pas
//
//PARAMETRES A DEFINIR EN TÊTE DE PROGRAMME
//
//CHOIX_INDIC=1----->SVAPO
//
//TYPE_DIV=1----->Divergence cachée en tendance haussière
//TYPE_DIV=2----->Divergence cachée en tendance baissière
//-----------------------------------------------------------

//Initialisations
//
CHOIX_INDIC=1
TYPE_DIV=2

IND(0)=SVAPO.SVAPO*(CHOIX_INDIC=1)
LIGNE1=SVAPO.HT
LIGNE2=SVAPO.BS


MINI=10000
MAXI=0

//Rechercher la divergence cachée éventuelle
//avant les P4 périodes qui pécèdent la FINHISTO
//
SI RANGHISTO=FINHISTO-P4 ALORS

//Rechercher un 1er creux (ou un 1er sommet) EI1
//sur l'indicateur et sa date DATE_EI1
//
I=0
EI1=MINI*(TYPE_DIV=1)+MAXI*(TYPE_DIV=2)
TANTQUE I<=P1 FAIRE
SI (IND(I+2)>IND(I+1) ET IND(I+1)<IND(I))*(TYPE_DIV=1)
OU (IND(I+2)<IND(I+1) ET IND(I+1)>IND(I))*(TYPE_DIV=2) ALORS
SI (IND(I+1)<=EI1)*(TYPE_DIV=1) OU (IND(I+1)>=EI1)*(TYPE_DIV=2) ALORS
EI1=IND(I+1)
DATE_EI1=FINHISTO-P4-(I+1)
D1=I+1
FINSI
FINSI
I=I+1
FINTANTQUE

SI D1=0 ALORS
AFFICHER "======PAS DE 1ER CREUX RECENT SUR L'INDICATEUR======="
AFFICHER "===============MODIFIEZ P1 ET/OU P4 ================="
STOP
FINSI

//Rechercher le 1er creux (ou le 1er sommet) correspondant EC1
//sur les cours et sa date DATE_EC1
//
EC1=BAS(FINHISTO-P4-DATE_EI1)*(TYPE_DIV=1)
+HAUT(FINHISTO-P4-DATE_EI1)*(TYPE_DIV=2)
DATE_EC1=DATE_EI1
K=FINHISTO-P4-DATE_EI1+1
TANTQUE K<=FINHISTO-P4-DATE_EI1+P3 FAIRE
SI (BAS(K)<=EC1)*(TYPE_DIV=1) OU (HAUT(K)>=EC1)*(TYPE_DIV=2) ALORS
EC1=(BAS(K))*(TYPE_DIV=1)+(HAUT(K))*(TYPE_DIV=2)
DATE_EC1=FINHISTO-K-P4
FINSI
K=K+1
FINTANTQUE

//Rechercher un 2ème creux (ou un 2ème sommet) EI2
//sur l'indicateur et sa date DATE_EI2
//
I=D1+1
EI2=EI1
TANTQUE I<=P2+D1 FAIRE
SI (IND(I+2)>IND(I+1) ET IND(I+1)<IND(I))*(TYPE_DIV=1)
OU (IND(I+2)<IND(I+1) ET IND(I+1)>IND(I))*(TYPE_DIV=2) ALORS
SI (IND(I+1)>=EI1)*(TYPE_DIV=1) OU (IND(I+1)<=EI1)*(TYPE_DIV=2) ALORS
EI2=IND(I+1)
DATE_EI2=FINHISTO-P4-(I+1)
D2=1
FINSI
FINSI

SI D2=1 //On a trouvé un creux (un sommet) EI2 possible
ALORS

SI P5=1 ALORS //La droite EI1--EI2 ne doit pas intersecter l'indicateur
PENTE_I=(EI1-EI2)/(DATE_EI1-DATE_EI2)
POUR (FINHISTO-P4-DATE_EI2+1) COURS
POINT_I(0)= PENTE_I*(RANGPOUR-1)+EI2
SI (POINT_I>IND)*(TYPE_DIV=1) OU (POINT_I<IND)*(TYPE_DIV=2) ALORS
N=1
BREAK
FINSI
SI RANGPOUR>(DATE_EI1-DATE_EI2) ALORS BREAK
FINPOUR
FINSI

SI N=0 ALORS //Droite de divergence correcte sur l'indicateur
//Rechercher le 2ème creux (ou le 2ème sommet) correspondant EC2
//sur les cours et sa date DATE_EC2
//
EC2=(BAS(FINHISTO-P4-DATE_EI2))*(TYPE_DIV=1)
+(HAUT(FINHISTO-P4-DATE_EI2))*(TYPE_DIV=2)
DATE_EC2=DATE_EI2
K=FINHISTO-P4-DATE_EI2+1
TANTQUE K<FINHISTO-P4-DATE_EI2+P3 FAIRE
SI (BAS(K)<=EC2)*(TYPE_DIV=1) OU (HAUT(K)>=EC2)*(TYPE_DIV=2) ALORS
EC2=BAS(K)*(TYPE_DIV=1)+HAUT(K)*(TYPE_DIV=2)
DATE_EC2=FINHISTO-K-P4
FINSI
K=K+1
FINTANTQUE

SI (EC2<=EC1)*(TYPE_DIV=1) OU (EC2>=EC1)*(TYPE_DIV=2) ALORS
SI P5=1 ALORS //La droite EC1--EC2 ne doit pas intersecter les cours
PENTE_C=(EC1-EC2)/(DATE_EC1-DATE_EC2)
POUR (FINHISTO-P4-DATE_EC2+1) COURS
POINT_C(0)=PENTE_C*(RANGPOUR-1)+EC2
SI (POINT_C>BAS)*(TYPE_DIV=1) OU (POINT_C<HAUT)*(TYPE_DIV=2) ALORS
M=1
BREAK
FINSI
SI RANGPOUR>(DATE_EC1-DATE_EC2) ALORS BREAK
FINPOUR
FINSI
SI M=0 ALORS //Droite correcte sur les cours
I=P2+D1+1
SINON
D2=0
FINSI
SINON
D2=0
FINSI
SINON
D2=0
FINSI
FINSI
N=0
M=0
I=I+1
FINTANTQUE

SI D1<>0 ET D2=0 OU EC2=0
ALORS
AFFICHER "============PAS DE DIVERGENCE POTENTIELLE============="
AFFICHER "======AVEC LES VALEURS ACTUELLES DES PARAMETRES======="
AFFICHER "===MAIS IL Y A UN 1ER CREUX SUR L'INDIC ET LES COURS=="
AFFICHER "==============MODIFIEZ EVENTUELLEMENT P2=============="
STOP
FINSI


//Déterminer les points des segments de la divergence
//cachée potentielle sur l'indicateur et les cours
//
SI DATE_EC1-DATE_EC2<5 ALORS //La valeur 5 peut être modifiée
AFFICHER "=============DIVERGENCE POTENTIELLE============"
AFFICHER "==========TROP PETITE POUR ETRE TRACEE========="
AFFICHER "===========MODIFIEZ EVENTUELLEMENT P4=========="
SINON
PENTE_I=(EI1-EI2)/(DATE_EI1-DATE_EI2)
POUR (FINHISTO-P4-DATE_EI2+1) COURS
SEG_I(0)=PENTE_I*(RANGPOUR-1)+EI2
SI RANGPOUR>(DATE_EI1-DATE_EI2) ALORS BREAK
FINPOUR

PENTE_C=(EC1-EC2)/(DATE_EC1-DATE_EC2)
POUR (FINHISTO-P4-DATE_EC2+1) COURS
SEG_C(0)=PENTE_C*(RANGPOUR-1)+EC2
SI RANGPOUR>(DATE_EC1-DATE_EC2) ALORS BREAK
FINPOUR
FINSI

FINSI


Et la fenetre propriétés:



Voici le programme de divergences cachées sur cours (indicateur dérivé):


//=================
//DCNC_SVAPO
//=================

//V1.0 du 08/02/2006
//

//Tracer le segment de la divergence cachée sur les cours
//

SEG_COURS=SEG_C


Et la fenetre propriétés:



Voici un exemple de divergences cachées négatives entre le SVAPO et les cours:

Bonjour Fred,


Bien reçu ton message en PV.
Vu le volume des docs, j'ai préféré t'envoyer un email à ton adresse free qui contient un zip des progs des divergences régulières que j'avais écrits pour MACD, STOCH, RSI et REPULSE ainsi que les 3 pdf promis des articles de Sylvain Vervoort sur SVAPO et son emploi.
J'ai oublié de te dire qu'il existe aussi des progs de règles statistiques qui permettent d'automatiser la recherche des divergences...

Cordialement.

Bonsoir à tous , est-ce que quelqu'un parmis vous a déjà programmer la technique des points pivots?

J'ai découvert cela au séminaire pro At avec Louis et je voudrais bien rentrer ce principe sur graphe AT pro.

Ce que j'ai trouvé sur le sujet si la programmation n'existe pas:

Les niveaux seront calculés avec les formules suivantes, formules qui qui utilisent les cotations de la veille.
Pivot = (H + B + C) / 3
S1 = (2 x Pivot) - H
S2 = Pivot - (H - B)
R1 = (2 x Pivot) - B
R2 = Pivot + (H - B)

S1 et S2 sont les deux supports
R1 et R2 sont les 2 résistances
H : cours le plus haut de la veille, B : le plus bas et C, le cours de clôture.

Pour le CAC cela donne pour la séance de demain (donc avec les cours de vendredi):
R2=4961.13
R1=4931
Pivot=4889.84
S1=4859.71
S2=4818.55

merci ftrillat

Citation de : ftrillat (au 06-04-2008 19:00:20)

Bonsoir à tous , est-ce que quelqu'un parmis vous a déjà programmer la technique des points pivots?

J'ai découvert cela au séminaire pro At avec Louis et je voudrais bien rentrer ce principe sur graphe AT pro.

Ce que j'ai trouvé sur le sujet si la programmation n'existe pas:

Les niveaux seront calculés avec les formules suivantes, formules qui qui utilisent les cotations de la veille.
Pivot = (H + B + C) / 3
S1 = (2 x Pivot) - H
S2 = Pivot - (H - B)
R1 = (2 x Pivot) - B
R2 = Pivot + (H - B)

S1 et S2 sont les deux supports
R1 et R2 sont les 2 résistances
H : cours le plus haut de la veille, B : le plus bas et C, le cours de clôture.

Pour le CAC cela donne pour la séance de demain (donc avec les cours de vendredi):
R2=4961.13
R1=4931
Pivot=4889.84
S1=4859.71
S2=4818.55

merci ftrillat

---

Bonsoir

Voir page 31 et 48 les prog sur les pivots

FOKI

Bonjour les graphatprotistes

Quelqu'un aurait il deja programmé l'auto force relative decrite par Mr Baron dans son bouquin sur le chartisme.

cela permet de savoir (en pourcentage) ou se situe l'action par rapport à son range des 12 derniers mois(voir semaine ou jour)

Merci pour votre contribution

Citation de : crnd (au 07-04-2008 16:37:47)

Bonjour les graphatprotistes

Quelqu'un aurait il deja programmé l'auto force relative decrite par Mr Baron dans son bouquin sur le chartisme.

cela permet de savoir (en pourcentage) ou se situe l'action par rapport à son range des 12 derniers mois(voir semaine ou jour)

Merci pour votre contribution

---

Bonjour crnd,

Tu trouveras la programmation de l'auto force relative page 74 de cette file.

forums-bourse/topic.php?TOPI... - Fredifly.

Merci Foki, j'ai rentré le programme avec le correctif jour pour avoir les niveaux du jour. Mais j'ai un petit problème : mes cours sont complètement écrasés quand je met l'indicateur dans le graphe. Voici ce que j'ai rentré dans graphe ATimage introuvable ou format inconnu

avec les images cette fois...!

Merci Fredifly pour votre rapidement réponse

Comment faites vous pour retouver si facilement tous les indicateurs deja programmés....il y actuellement tout de meme 118 pages...possedez vous une table des matieres??

Bonsoir crnd,


Toutes mes excuses à Fred à qui était destiné la question que tu poses.
Mais comme j'y ai déjà répondu de nombreuses fois, je me permets de recommencer.

Effectivement retrouver un sujet n'est pas chose aisée vu l'ampleur qu'a prise notre file.

Trois solutions :

1- Tu peux demander à notre ami Laurent de t'envoyer son super tableau Excel qui te permettra d'accèder directement sur Internet à n'importe quel sujet de notre file en un seul clic de souris.

2- Notre ami Jean-Luc fait aussi un travail considérable puisqu'il compile ttes les pages de la file sous fichiers Word et ce depuis le début en 2003.

Je te communique leurs adresses emails par message privé dans ta bal sur le forum afin que tu puisses leur demander de t'inscrire dans leurs listes d'envoi.

3- Enfin il y a toujours la possibilité d'utiliser le moteur de recherche du site a condition d'utiliser les bons mots clés bien sûr...

Cordialement.

Bonsoir ftrillat,


Je pense que ton pb de représentation provient du choix que tu as fait pour l'affichage de tes pivots avec le type de courbe "Simple" dans la fenêtre Propriétés de la règle.
En effet le type "Simple" représente chaque courbe même si sa valeur vaut 0. Ce qui est la cas pour ttes les périodes sauf la dernière. D'où l'écrasement du graphe que tu constates.

Choisis le type "Tirets" ou encore "Segments" qui ne présentent pas cet inconvénient.

Cordialement.

Ok merci smallcaps90 c'était bien là le problème d'écrasement avec ton conseil tout fonctionne.Ah là là si t'étais pas là, j'aurais plus qu'à m'arracher les cheveux

merci smallcaps90....je t'ai repondu par mail

Bonjour,

Message envoyé en PV à quelques amis de la file pour prendre leur avis :

"J'avais ces temps derniers pensé initier une nouvelle file qui aurait justement travaillé sur les systèmes de trading exclusivement.
Nous disposons d'une foultitude d'indicateurs qui tournent de façon fiable maintenant, mais d'assez peu de systèmes de trading intéressants et/ou finalisés qui ont été publiés.
Avec GrapheAT Pro nous avons pourtant d'un superbe outil : les "règles statistiques", pour reprendre le langage de MLOG. Elles offrent nombre de possibilités même si elles sont encore un peu limitées dans certains cas et on on n'en utilise pas toujours tout le potentiel.

Il y a vraisemblablement quelques utilisateurs du logiciel qui ont réfléchi au problème et qui pourraient nous faire part de leurs idées, abouties ou non.

A partir de là nous pourrions engager un travail collaboratif pour faire évoluer des outils dont on ressent bien la nécessité car la majorité des utilisateurs du logiciel n'ont pas de méthode définitive et en cherchent peut-être une...
Qu'en pensez-vous? "


Merci de donner ici votre avis également si cela vous intéresse.

Cordialement.