Bonjour belonda,


Nous avons tous débuté un jour...je pense qu'avec l'aide en ligne de GrapheAT Pro, même succincte, avec les très nombreux exemples présentés dans les posts de la présente file et le niveau d'entraide qui y règne, tu pourras progresser si tu veux t'investir dans la programmation.
Je vais tout d'abord tenter de répondre à tes questions.

1- NB_COURS=5 :
Une règle statistique s'exécute normalement et uniquement sur le dernier cours de l'historique des valeurs du groupe sélectionné pour le scan.
On peut la faire exécuter sur une autre date si on le souhaite, il suffit alors de modifier cette date en haut dans la fenêtre "Statistiques" qui apparaît en actionnant les menus : "Outils/Statistiques...".
Mais si tu veux qu'elle s'applique sur plusieurs dates en amont de la dernière de l'historique, tu seras obligé de créer une répétitive (Pour/FinPour ou TantQue Faire/FinTantQue) qui lui forcera d'examiner ces cours.
NB_COURS=5 en l'occurence indique combien de périodes on souhaite que la stat scanne en amont de la dernière et y compris celle-ci, s'il s'agit d'une boucle Pour/FinPour.
Avec une boucle TantQue Faire/FinTantQue, on peut situer une tranche de périodes quelconque, celle-ci étant référencée par rapport à la dernière de l'historique.

2- Non on ne démarre pas toujours ainsi cela dépend du pb à résoudre bien sûr.

3- Pour faire appel à la différence de deux moyennes mobiles exponentielles dans la stat mais aussi plus généralement à des variables sur lesquelles la stat va travailler, tu as deux solutions à ta disposition :
- la première consiste à créer un (ou des indicateurs) qui va (vont) générer les variables en question, variables que la stat devra récupèrer ;
-la deuxième consiste à placer directement la partie de programme qui créé ces variables dans la stat elle-même. Ceci dans le cas où tu n'aurais pas besoin de visualiser les indicateurs sous les cours. C'est ce que je ferai pour ta stat sur les MACD plus loin.

4- Comme la stat scanne un groupe de plusieurs valeurs, en général, on ne peut pas créer de titres indépendants dans l'éditeur des résultats. Ou alors il faudrait créer une action fictive dans le groupe à scanner qui lorsque la stat l'examinerait créerait spécifiquement ces titres...
Si on choisit bien les intitulés textes des colonnes, on peut très bien se passer de titres.
Pas forcément relié directement à cette question, tu trouveras page 64 de la file un post du 21/09/2005 en réponse à lego sur une stat multiple qui montre ce que l'on peut faire pour "éclaicir" le tableau final des résultats.


Pour répondre maintenant à ton pb spécifique d'examen des MACD qui t'intéressent, j'ai écrit le programme d'une stat qui semble fonctionner et dont les résultats sont assez facilement lisibles sans titre.

Programme de la stat :

//===========
//Stat_3_MACD
//===========

//v0.1 PROTO
//le 01/03/2009
//smallcaps90
//=============

//========= 1 Calcul des trois MACD
//
Pour 100 Cours
ME1=Exposuiv(ME1,Cloture,2)
ME2=Exposuiv(ME2,Cloture,9)
MACD2_9(0)=ME1-ME2

ME3=Exposuiv(ME3,Cloture,12)
ME4=EXPOSUIV(ME4,Cloture,26)
MACD12_26(0)=ME3-ME4

ME5=Exposuiv(ME5,Cloture,24)
ME6=Exposuiv(ME6,Cloture,56)
MACD24_56(0)=ME5-ME6
FinPour

//========= 2 Traitement de la MACD 2,9
//
Si MACD2_9>MACD2_9(1)
Alors
Colonne1="2_9 en hausse "
Si MACD2_9>0
Alors
Colonne2=">0"
Sinon
Colonne2="<0"
FinSi
Sinon
Colonne1="2_9 en baisse "
Si MACD2_9>0
Alors
Colonne2=">0"
Sinon
Colonne2="<0"
FinSi
FinSi

//========= 3 Traitement de la MACD 12,26
//
Si MACD12_26>MACD12_26(1)
Alors
Colonne3="12_26 en hausse "
Si MACD12_26>0
Alors
Colonne4=">0"
Sinon
Colonne4="<0"
FinSi
Sinon
Colonne3="12_26 en baisse "
Si MACD12_26>0
Alors
Colonne4=">0"
Sinon
Colonne4="<0"
FinSi
FinSi

//========= 4 Traitement de la MACD 24,56
//
Si MACD24_56>MACD24_56(1)
Alors
Colonne5="24_56 en hausse "
Si MACD24_56>0
Alors
Colonne6=">0"
Sinon
Colonne6="<0"
FinSi
Sinon
Colonne5="24_56 en baisse "
Si MACD24_56>0
Alors
Colonne6=">0"
Sinon
Colonne6="<0"
FinSi
FinSi

//Fin du code

Fenêtre Propriétés de la stat :



Quelques explications.
Comme dit plus haut, j'ai intégré les calculs des trois MACD dans la stat.
Ces calculs se font dans une boucle Pour/FinPour sur les 100 périodes en fin d'historique. La valeur 100 peut-être modifiée évidemment (code après le commentaire1).

Ensuite chaque MACD est examiné (codes qui suivent les commentaires 2, 3 et 4).
Pour ce faire j'utilise tout simplement des tests "Si/Alors/Sinon/FinSi" imbriqués qui vérifient la tendance et le signe de chaque MACD sur la dernière période de l'historique et qui placent les résultats obtenus pour chaque valeur scannée dans des colonnes ad-hocs du tableau des résultats. Ceci suffit pour répondre à ton cahier des charges.
Plus besoin d'indiquer de dates puisqu'on est situé à la dernière période de l'historique.
Plus besoin de boucle non plus ensuite pour la même raison.
Plus besoin enfin de la variable "VarSelect" puisque TOUTES les valeurs du groupe que tu sélectionnes seront scannées.
Comme tu le constates, le programme est très simple.

En date du 27/02/2009 dernier cela donne en mode JOUR pour le CAC40 :

=====================================
Groupe : cac40 Date : 27/02/2009
Statistique d'examen de trois MACD pour trouver leur tendance et leur signe.

2_9 en baisse <0 12_26 en baisse <0 24_56 en baisse >0 Accor
2_9 en baisse <0 12_26 en baisse <0 24_56 en baisse <0 Air France KLM
2_9 en baisse <0 12_26 en baisse <0 24_56 en baisse >0 Air Liquide
2_9 en baisse <0 12_26 en baisse <0 24_56 en baisse >0 Arcelor Mittal
2_9 en baisse <0 12_26 en baisse <0 24_56 en baisse <0 Axa
2_9 en baisse >0 12_26 en hausse <0 24_56 en hausse <0 Bnp Paribas
2_9 en baisse <0 12_26 en baisse <0 24_56 en baisse >0 Cap Gemini
2_9 en baisse >0 12_26 en hausse <0 24_56 en baisse <0 Credit agricole SA
2_9 en baisse <0 12_26 en baisse <0 24_56 en baisse <0 Essilor International
2_9 en baisse <0 12_26 en baisse <0 24_56 en baisse <0 Lafarge
2_9 en baisse <0 12_26 en baisse >0 24_56 en baisse >0 LVMH
2_9 en baisse <0 12_26 en baisse <0 24_56 en baisse <0 Michelin
2_9 en baisse <0 12_26 en baisse <0 24_56 en baisse >0 Sanofi-Aventis
2_9 en baisse <0 12_26 en baisse <0 24_56 en baisse >0 Schneider Electric
2_9 en baisse >0 12_26 en hausse <0 24_56 en baisse <0 Societe Generale
2_9 en baisse <0 12_26 en baisse <0 24_56 en baisse <0 STMicroelectronics
2_9 en baisse <0 12_26 en baisse <0 24_56 en baisse >0 Total
2_9 en baisse <0 12_26 en baisse <0 24_56 en baisse <0 Vallourec
2_9 en baisse <0 12_26 en baisse <0 24_56 en baisse >0 Vinci
2_9 en hausse <0 12_26 en baisse <0 24_56 en baisse <0 Alcatel Lucent
2_9 en hausse <0 12_26 en hausse <0 24_56 en baisse >0 Alstom
2_9 en hausse <0 12_26 en baisse <0 24_56 en baisse <0 Bouygues
2_9 en hausse <0 12_26 en hausse <0 24_56 en baisse >0 Carrefour
2_9 en hausse >0 12_26 en hausse <0 24_56 en baisse <0 Danone
2_9 en hausse <0 12_26 en baisse <0 24_56 en baisse <0 Dexia
2_9 en hausse <0 12_26 en baisse <0 24_56 en baisse >0 Eads
2_9 en hausse <0 12_26 en hausse <0 24_56 en baisse <0 EDF
2_9 en hausse >0 12_26 en hausse <0 24_56 en baisse <0 France Telecom
2_9 en hausse <0 12_26 en baisse <0 24_56 en baisse <0 GDF Suez
2_9 en hausse <0 12_26 en hausse <0 24_56 en baisse <0 L'Oreal
2_9 en hausse <0 12_26 en baisse <0 24_56 en baisse >0 Lagardere
2_9 en hausse <0 12_26 en baisse <0 24_56 en baisse >0 Pernod Ricard
2_9 en hausse <0 12_26 en baisse >0 24_56 en baisse >0 Peugeot
2_9 en hausse >0 12_26 en hausse >0 24_56 en hausse >0 PPR
2_9 en hausse <0 12_26 en baisse <0 24_56 en baisse <0 Renault
2_9 en hausse <0 12_26 en baisse <0 24_56 en baisse <0 Saint Gobain
2_9 en hausse <0 12_26 en baisse <0 24_56 en baisse >0 Suez Environnement
2_9 en hausse <0 12_26 en baisse <0 24_56 en baisse >0 Unibail-Rodamco
2_9 en hausse >0 12_26 en hausse <0 24_56 en hausse <0 Veolia Environnement
2_9 en hausse <0 12_26 en hausse <0 24_56 en baisse <0 Vivendi
=====================================

Pour ce qui concerne maintenant les trois UT que tu choisis, on peut recopier le programme ci-dessus sous plusieurs des trois onglets Jour, Semaine, Mois de la fenêtre "Règle Statistique" qui s'ouvre lorsqu'on clique sur l'onglet "Règle..." de la fenêtre "Statistiques" accessible par les menus "Outils/Statistiques".
Normalement seules les valeurs qui satisfont A LA FOIS à tous les programmes présents dans les onglets Jour, Semaine, Mois sont sélectionnées dans le tableau final.
Ici on ne sélectionne rien. Il vaut peut-être mieux que tu génères les résultats en plaçant le programme de la stat dans l'onglet Jour puis ensuite uniquement dans l'onglet Semaine puis enfin dans l'onglet Mois.
Je n'ai pas examiné ce qu'on obtiendrait si le programme était présent sous les trois onglets en même temps...

Voilà ce que je peux te dire pour le moment.
Si tu as des questions, n'hésite pas.

Cordialement.

=========================================================
Mille excuses pour cette "triplette" due à une fausse manoeuvre. Le Webmaster est prévenu et devrait supprimer sous peu les posts redondants...
=========================================================


Bonsoir Papy29,

Je n'ai pas le programme dont tu aurais besoin mais il serait possible de le créer en cumulant le nombres des gains d'une part et celui des pertes d'autre part.
Le pb que j'y vois cependant, je t'en ai déjà parlé, est que le filtre de Hodrick-Prescott repeint le passé, attention !!!
Par conséquent si tu fais une recherche des signaux d'achat/vente avec le filtre tracé sur la totalité de ton historique, en faisant évoluer simplement la date à laquelle tu exécutes la statistique "STAT_HODRICK_PRESCOTT" du 03/11/2008 au 17/02/2009, date après date, avec N=1 pour n'examiner que le jour sélectionné, comme je le comprends d'après ce que tu dis, eh bien tu travailles sur la courbe du filtre qui est repeinte et le score des gains frôle les 100% ou presque parce que certains signaux d'achat/vente sont modifié. Trop beau donc pour être vrai...surtout si tu avances encore les signaux d'achat/vente comme tu le fais par rapport à la stratégie "prudente" que j'avais proposée.

Pour que le résultat que tu obtiens soit fiable, il faut obligatoirement que la courbe du filtre s'arrête au jour où tu lances la statistique pour que le phénomène de repeinte du passé ne vienne pas modifier éventuellement les signaux d'achat/vente que tu as précédemment envoyé à exécution. Je ne sais pas si j'ai été assez clair?

Il faudrait donc modifier le programme "HODRICK_PRESCOTT" pour l'arrêter à chaque période que tu examines entre tes deux dates limites. Je regarderai cela dès que j'aurai un moment. Bel os à ronger...

GrapheAT Pro charge en mémoire la totalité des historiques. Il serait intéressant comme nous l'avons demandé à MLOG de pouvoir n'en charger qu'une partie en l'occurence.

Pour ce qui concerne ton pb de style, je ne vois vraiment pas pourquoi il ne garde pas "HP_AV " dans tes règles indicateurs lorsque tu changes de style ou que tu ouvres GrapheAT Pro.
Peut-être devrais-tu demander à MLOG ce qu'il en pense?

Cordialement.

Bonsoir Smallcaps;
je t'envoie ci après le comparatif calcul du canal et de channel.
Comme tu peux le voir, il n'y a pas de différence majeure et pour moi qui veux sélectionner les valeurs dont le canal est le plus large possible cela me va très bien. En gros les gagnants sont les mêmes que pour la stat volatilité
Je te remercie très fort car ton programme me fait gagner 1heure 30 à 2 heures de travail par semaine. Et je peux l'actualiser tous les jours. De plus je visualise instantanément la position du cours part rapport aux bornes du canal. sans avoir à passer par le calcul de l'écart.
En ce qui concerne le nombre de cours, j'ai pris trente pour rendre le programme sensible aux derniers cours seulement.
Pour ce qui est de l'affichage des bandes expérieures, je n'ai pas pris P3 mais une valeur de 300 ce qui permet d'avoir un canal complet à l'écran avec un calcul sur trente jours
nom Channel 27/02/09 nom Canal 27/02/09
Axa 32 Axa 30
Saint Gobain 32 Saint Gobain 30
Bnp Paribas 30 Bnp Paribas 29
Wendel Invest. 28 Wendel Invest. 29
Remy Cointreau 27 Thomson 28
Thomson 27 Societe Generale A 24
Societe Generale A 25 Euler Hermes 23
Euler Hermes 24 Hsbc Holdings 23
Renault 24 Remy Cointreau 23
Gecina Nom. 23 Renault 23
Hsbc Holdings 23 Tf1 23
Air France - KLM 22 Gecina Nom. 22
Nexans 22 Nexans 22
Rhodia 22 Safran 22
Safran 22 Air France - KLM 21
Tf1 22 Rhodia 21
Alcatel-Lucent 21 Alcatel-Lucent 20
Allianz 21 General Electric 20
General Electric 21 Kaufman Et Broad 20
Kaufman Et Broad 21 Eurazeo 19
Natixis 21 Manitou Bf 19
Alten 20 Nexity 19
Beneteau 20 Soitec Silicon 19
Eurazeo 20 Allianz 18
Manitou Bf 20 Alten 18
Nexity 20 CGG Veritas 18
Ubi Soft Entertain 20 Ubi Soft Entertain 18
Veolia Environ. 20 Valeo 18
Lafarge 19 Arkema 17
Soitec Silicon 18 Lafarge 17
Sperian Protection 18 Sperian Protection 17
Valeo 18 April Group 16
Vallourec 18 Bouygues 16
April Group 17 EDF 16
Arkema 17 Harmony Gold 16
CGG Veritas 17 Metropole Tv 16
Credit Agricole 17 Michelin 16
Ingenico 17 Natixis 16
Seb 17 Rallye 16
Steria (Groupe) 17 Rexel 16


Merci encore et bonne soirée.

Bonjour smallcaps90
je tiens vraiment à te remercier
je comprends un peu mieux comment çà marche.
Ton travail, ton assistance sur cette file sont vraiment exemplaires.
Cordialement

Bonjour à Tous,

Je cherche à introduire SuperTrend de Seban dans GraphePro sans succès.

Il dit qu'il faut prendre 3 fois la moyenne des 10 derniers range qu'on ajoute ou retranche du milieu du chandelier en cours.

Basiquement j'ai fait ainsi :

sp= (haut+bas)/2
sp1=haut(1)-bas(1)
sp2=haut(2)-bas(2)
sp3=haut(3)-bas(3)
sp4=haut(4)-bas(4)
sp5=haut(5)-bas(5)
sp6=haut(6)-bas(6)
sp7=haut(7)-bas(7)
sp8=haut(8)-bas(8)
sp9=haut(9)-bas(9)
sp10=haut(10)-bas(10)

M=sp1+sp2+sp3+sp4+sp5+sp6+sp7+sp8+sp9+sp10
MM=M/10
MM3=MM*3

Courbe = sp+MM3

Bien entendu ce n’est pas le bon raisonnement ;-(

Si quelqu'un à déjà la formule magique pour notre logiciel préféré, je l'en remercie par avance.

@+
francis

Bonjour à Tous,

Je cherche à introduire SuperTrend de Seban dans GraphePro sans succès.

Il dit qu'il faut prendre 3 fois la moyenne des 10 derniers range qu'on ajoute ou retranche du milieu du chandelier en cours.

Basiquement j'ai fait ainsi :

sp= (haut+bas)/2
sp1=haut(1)-bas(1)
sp2=haut(2)-bas(2)
sp3=haut(3)-bas(3)
sp4=haut(4)-bas(4)
sp5=haut(5)-bas(5)
sp6=haut(6)-bas(6)
sp7=haut(7)-bas(7)
sp8=haut(8)-bas(8)
sp9=haut(9)-bas(9)
sp10=haut(10)-bas(10)

M=sp1+sp2+sp3+sp4+sp5+sp6+sp7+sp8+sp9+sp10
MM=M/10
MM3=MM*3

Courbe = sp+MM3

Bien entendu ce n’est pas le bon raisonnement ;-(

Si quelqu'un à déjà la formule magique pour notre logiciel préféré, je l'en remercie par avance.

@+
francis

Bonjour Asynergy,


Tu avais calculé l'ATR sur 10 périodes mais uniquement l'un des segments du Super_Trend de O.Seban, en l'occurence celui qui est au dessus des cours quand ceux-ci sont en trend baissier. Et puis il te restais aussi à gèrer quel segment conserver à chaque instant suivant que le trend est haussier ou baissier...

Voici une version qui tourne du Super_Trend de O.Seban sur GrapheAT Pro. Je ne l'ai pas comparée à la version PRT, ce serait peut-être intéressant à faire.

Programme :

//===========
//SUPER_TREND
//===========

//v1.0 d'après O. Seban (à valider)
//le 02/03/2009
//smallcaps90
//=============


Si RangHisto=1 Alors
Trend=1 //initialisation
Sinon
//Ingrédients
//
TR(0)=MAXVAL(HAUT,CLOTURE(1))-MINVAL(BAS,CLOTURE(1))
MTR=Moyenne(TR,P1) //conforme à ATR
PM=(Haut+Bas)/2 //prix moyen
Up(0)=PM+P2*MTR //segment en trend baissier
Down(0)=PM-P2*MTR //segment en trend haussier

//Changement de tendance?
//
Si Cloture<Down(1)
Alors
Trend=-1 //passage en trend baissier
FinSi
Si Cloture>Up(1)
Alors
Trend=1 //passage en trend haussier
FinSi

//Filtrage des segments
//
Si Trend=1 ET Down<Down(1) Alors Down=Down(1)
Si Trend=-1 ET Up>Up(1) Alors Up=Up(1)

//Choix du segment sur le Super_Trend
//
Si Trend=1
Alors
SUPER_TREND=Down
Sinon
SUPER_TREND=Up
FinSi

FinSi

//Fin du code

Fenêtre Propriétés :


Exemple avec PPR :

Indicateur seul :


Indicateur avec les courbes Up et Down à titre d'illustration :



Remarque :

Il existe de nombreux indics de ce genre qui suivent les tendances (avec plus ou moins de retard) à l'image d'un stop suiveur ou du SAR. Si cela peut intéresser, j'ai retenu le "Abraham Trend Indicator" de Andrew Abraham présenté dans TASC de sept 1998. Il est proche de celui de Seban.
Enfin un autre aussi, que j'utilise parfois, récupéré d'un forum sur MT4 et qui associe le CCI et l'ATR.

Programme :

//===================
//ABRAHAM_TREND_INDIC
//===================

//v1.0
//le 03/03/2009
//smallcaps90
//===================

Si RangHisto=1
Alors
HC=-100000
LC=100000
FinSi

Si RangHisto>=P2 Alors

TR(0)=MaxVal(Haut,Cloture(1))-MinVal(Bas,Cloture(1))
V1=P1*Pondere(TR,P2)
Si RangHisto=P2 Alors V2=HC-V1

Si Cloture>HC
Alors
HC=Cloture
FinSi

Si Cloture<LC
Alors
LC=Cloture
FinSi

Si Cloture<V2
Alors
V2=LC+V1
HC=Cloture
FinSi

Si Cloture>V2
Alors
V2=HC-V1
LC=Cloture
FinSi

V3(0)=V2
ATI=V3(1)

FinSi

//Fin du code

Fenêtre Propriétés :


Avec le même PPR que ci-dessus :



Voici enfin celui qui utilise le CCI et l'ATR .

Programme :

//===============
//SUPER_TREND_CCI
//===============

//smallcaps90 le 3/7/2006


//CCI20
//
MO=MOYENNE((HAUT+BAS+CLOTURE)/3,P2)
DEVIA=MOYENNE(ABSOLU(HAUT+BAS+CLOTURE)/3-MO,P2)
CCI20(0)=(HAUT+BAS+CLOTURE)/3-MO

//ATR5
//
TR5(0)=MAXVAL(HAUT,CLOTURE(1))-MINVAL(BAS,CLOTURE(1))
ATR5=MOYENNE(TR5,P3)

//Règles
//
CCI_ACTU=CCI20(0)
CCI_PRECED=CCI20(1)

SI CCI_ACTU>=P1 ET CCI_PRECED<P1 ALORS TR_UP(1)=TR_DN(1)

SI CCI_ACTU<=P1 ET CCI_PRECED>P1 ALORS TR_DN(1)=TR_UP(1)

SI CCI_ACTU>=P1
ALORS
TR_UP=BAS-ATR5
SI TR_UP<TR_UP(1) ALORS TR_UP=TR_UP(1)
FINSI

SI CCI_ACTU<=P1
ALORS
TR_DN=HAUT+ATR5
SI TR_DN>TR_DN(1) ALORS TR_DN=TR_DN(1)
FINSI

//Fin du Code

Fenêtre Propriétés :


Même exemple PPR :


A partir de là, fais toi une opinion, parfois il n'y a pas photo...

Cordialement.

Bonjour SmallCaps90

Toujours aussi généreux !

Grand merci, je vais regarder tes 3 propositions en détail

Mais manifestement ce n’est pas la panacée et à consulter en symbiose avec les chandeliers et des momentums

Encore merci !
francis

Bonjour Smallcaps

merci pour ta réponse
lors de ta première intervention je n’avais pas bien saisi le Pb de repeindre le passé, mais depuis avec plusieurs test en chargent les cotations au jour le jour et en comparant les résultats sur Excel, j’ai eu des surprises parfois l’indicateur HP_CONV_CONC revient 2 a 3 jours en arrière ou disparaît , tu as raison c’était trop beau
par contre il donne des indications sur la tendance
je vais refaire des tests avec ta stratégie prudente

pour le Pb de style je vais contacter mlog

cordialement

Bonjour Smallcaps

Je ne comprends pas ta formule CCI dans le "super_trend_cci"

MO=MOYENNE((HAUT+BAS+CLOTURE)/3,P2)
DEVIA=MOYENNE(ABSOLU(HAUT+BAS+CLOTURE)/3-MO,P2)
CCI20(0)=(HAUT+BAS+CLOTURE)/3-MO
elle ne prends en compte la deviation

je l'ai comparé avec celle du triplecciwood....ne devrait elle pas plutot s'ecrire comme ci dessous??

MO = MOYENNE((Haut+Bas+Cloture)/3,P2)
DEVIA = MOYENNE(ABSOLU((Haut+Bas+Cloture)/3-MO),P2)
CCI20(0)=((haut+Bas+Cloture)/3-MO)/(0.015 * DEVIA)

Merci d'avance et on week end

Bonjour crnd,


Oui je vois il y a eu un "joyeux" mélange, excuse-m'en.
En fait le programme date de juillet 2006 et n'avait pas été publié sur le forum. J'y avais testé diverses versions dont la version CCI et je m'étais rendu compte qu'avec ce CCI "classique" les résultats étaient moins bons qu'avec un simple oscillateur de moyennes dont le programme est bien celui qui a été posté le 03/03 dernier. L'identificateur "CCI20" est évidemment impropre ainsi que son nom "SUPER_TREND_CCI".


Voici le programme "repeigné" et renommé "SUPER_TREND_OSC" :

//===============
//SUPER_TREND_OSC
//===============

//V2.0
//le 14/03/2009
//smallcaps90
//===============


//Oscillateur de moyenne
//
MO=Moyenne((Haut+Bas+Cloture)/3,P1)
Osc(0)=((Haut+Bas+Cloture)/3-MO)

//ATR5
//
Tr5(0)=MaxVal(Haut,Cloture(1))-MinVal(Bas,Cloture(1))
ATR5=Moyenne(Tr5,P2)

//Règles
//
Si Osc>0 ET Osc(1)<0 Alors TR_UP(1)=TR_DN(1)

Si Osc<0 ET Osc(1)>0 Alors TR_DN(1)=TR_UP(1)

Si Osc>0
Alors
TR_UP=Bas-ATR5
Si TR_UP<TR_UP(1) Alors TR_UP=TR_UP(1)
FinSi

Si Osc<0
Alors
TR_DN=Haut+ATR5
Si TR_DN>TR_DN(1) Alors TR_DN=TR_DN(1)
Finsi

//Fin du Code

Fenêtre Propriétés :



En comparaison, la version Oscillateur de Moyenne et la version CCI qui tient donc compte de la variable DEVIA est moins "nette".
Voici les graphes daily pour PPR :





Avec la version Oscillateur de Moyenne, les performances sont aussi meilleures.
Pour la CAC40 un petit backtest daily sur les 500 dernières périodes (environ 2 ans) donne 37 valeurs avec un gain positif alors qu'avec la version CCI on n'en a que 22.

Je posterai ceci dans la file dédiée aux système de trading.

Cordialement.

Bonjour

Est-ce que quelq'un qui connait graphe AT Pro et TS saurait transcrire "SUPER_TREND_OSC" en easylanguage de TS

Merci et salutations
VIVI

Gruëzi VIVI,

Comme personne ne se lance, je te réponds.
Je n'utilise pas Tradestation aussi je ne te garantis pas que ma traduction en EasyLanguage de "SUPER_TREND_OSC" soit exempte de bugs syntaxiques...
J'en ai fait une image à cause des indentations :



Cordialement.

Bonjour

et merci smallcaps

cordiales salutations
VIVI

Bonsoir,


"Quelques nouvelles du front" :

Je viens de recevoir un email de Mr Metois de MLOG qui m'informe de l'avancement du projet de la future version 3.09 de GrapheAT Pro.
Le voici :

Bonjour,

Dans la nouvelle version 3.09, on pourra choisir le caractère graphique
affiché parmi tous ceux des polices spéciales Wingdings et Webdings (voir
écrans ci-joints). On pourra les choisir aussi dans les commentaires (hors
programmation).

Un nouveau type permet d'avoir un histogramme à 2 bornes (comme vous êtes
demandeur je crois). Cela permet d'implémenter la représentation Heikin Ashi
par exemple.

Cordialement.

Trois images jointes à l'email.
La police Wingdings :


Les types "O" et "X" pour le développement en cours d'une représentation en "point et figure" à laquelle je travaille :



Un exemple d'emploi du nouveau type de courbes "Histogramme à deux limites différentes de 0" demandé et son utilisation pour la reprentation en Heiken Ashi des cours :



Un grand merci à lui.

Cordialement.