Bonsoir Smallcaps90

Pour faire court suite à ton dernier post :

- à mon humble avis les "plus proches de la clôture actuelle", ne voyant pas l'utilité de visualiser des SR que nous ne reverrons qu'aux "calendes grecques".


Maintenant, après réflexion, à laquelle tu m'entraînes… pourquoi pas "les plus proches de la clôture actuelle… dont le poids est le plus fort" ?

Du genre "les plus proches de la clôture actuelle… dont le poids" serait >= au 2/3 de la moyenne des X (jusqu'à ce que nous ayons nos 10) plus proches de la clôture actuelle.
Il est vrai que cela éviterait les SR mineures sans que nous ayons à revoir les calendes grecques.

Mais bon avec mon niveau de 3ème des collèges...

Cordialement

PS à Smallcpas :

Tout a fait d'accord avec ta proposition d'une "droite de régression linéaire à n périodes"... "plutôt qu'une moyenne fût-elle exponentielle".

Cordialement

Pour Jean-Luc M.

merci pour l'envoi des pp79 à 81 par mail ;

en réponse à ta demande, un livre qui expose une manière de déterminer les supports et résistances, totalement graphique, c'est Weinstein, "secrets pour gagner en bourse".

Sinon, il y a aussi des logiciels (pas trouvé sur graphe AT) qui déterminent le volume cumulé à chaque niveau de prix ; si le volume cumulé est élevé, c'est un support/resistance valide.

J'espère que cela t'aide ...

Bonjour jmc,

Un travail a été fait sur les supports/résistances liés aux volumes cumulés ici même page 49 et 57 .
Cordialement.

Bonsoir Débutant13,

Je te livre un premier proto du programme "RS_Histos" qui fonctionne alors qu'il est loin d'être optimisé en terme de temps d'exécution.
J'y ai en particulier réintégré le calcul de la pente de la régression linéaire des clôtures sur 3 jours alors qu'il aurait été possible de récupérer cette valeur en utilisant le programme correspondant déjà disponible dans nos bibliothèques d'indicateurs.
J'ai retenu comme méthode de sélection des droites à tracer, la proximité de la clôture actuelle comme premier critère auquel j'ai associé en deuxième lieu l'importance du nombre d'impacts du cours dans les plages de prix.

PROGRAMME :

//=========
//RS_Histos
//=========

//VProto 1.3
//le 06/09/06


//----------------------1/- Choix du prix
//
MEDIAN_PRICE=(HAUT+BAS)/2
TYPICAL_PRICE=(HAUT+BAS+CLOTURE)/3
PRIX(0)=CLOTURE*(P1=1)+MEDIAN_PRICE*(P1=2)+TYPICAL_PRICE*(P1=3)

SI RANGHISTO=FINHISTO
ALORS

//----------------------2- Calculer la droite de régression des 3 dernières clotures
POUR 3 COURS
XR(0) = RANGPOUR
YR(0) = PRIX
FINPOUR
SOMX = SOMME(XR,3)
SOMY = SOMME(YR,3)
SOMXX = SOMME(XR*XR,3)
SOMXY = SOMME(XR*YR,3)
A = (3*SOMXY-SOMX*SOMY)/(3*SOMXX-SOMX*SOMX) //pente régression linéaire

//----------------------3/- Recherche du Plus Haut et du Plus Bas de l'historique
//
ValH=MAX(PRIX,FINHISTO)
ValB=MIN(PRIX,FINHISTO)

//----------------------4/- Création des numéros des plages et de leurs limites
//
J=0
TANTQUE J<=1/P2%-1 FAIRE //boucle sur les limites des plages
N_Plage(J)=(J+1)
LIM_SUP(J)=ValH-(ValH-ValB)*J*P2%
LIM_INF(J)=ValH-(ValH-ValB)*(J+1)*P2%
DIST(J)=LIM_SUP(J)-CLOTURE(0)
J=J+1
FINTANTQUE

//----------------------5/- Repèrage des positions des prix par rapport aux plages
//
I=0
TANTQUE I<=FINHISTO-1 FAIRE //boucle sur l'historique
J=0

TANTQUE J<=1/P2%-1 FAIRE
SI PRIX(I)<=LIM_SUP(J) ET PRIX(I)>LIM_INF(J)
ALORS
PLAGE_PRIX(I)=LIM_SUP(J)
NO_PLAGE(I)=J+1
FINSI
J=J+1
FINTANTQUE
I=I+1
FINTANTQUE

//----------------------6/- Compter le nombre d'occurence de chaque impact
//
I=0
TANTQUE I<=1/P2%-1 FAIRE
CPT=0
J=0
TANTQUE J<=FINHISTO-1 FAIRE
SI NO_PLAGE(J)=N_Plage(I)
ALORS
CPT=CPT+1
FINSI
J=J+1
FINTANTQUE
CPT_N(I)=CPT
I=I+1
FINTANTQUE

//----------------------7/- Calculer les moyennes des poids des impacts + et -
//
I=0
TANTQUE I<=1/P2%-1 FAIRE
SI DIST(I)>=0
ALORS
P=P+CPT_N(I)
NBP=NBP+1
SINON
N=N+CPT_N(I)
NBN=NBN+1
FINSI
I=I+1
FINTANTQUE

//Moyennes des poids + et -
MPP=P/NBP
MPN=N/NBN

//----------------------8/- Déterminer le nombre de DIST>=0
//
K=0
TANTQUE DIST(K)>=0 FAIRE
K=K+1
FINTANTQUE

//----------------------9/- Sélectionner les plages à tracer
//Résistances
I=K-1
J=0
TANTQUE I>=0 FAIRE
SI CPT_N(I)>=P3*MPP
ALORS
Y(J)=LIM_SUP(I)
CPT_NM(J)=CPT_N(I)
J=J+1
SI (J=6)*(A>=0) OU (J=4)*(A<0) ALORS BREAK
FINSI
I=I-1
FINTANTQUE

//Supports
I=K
N=J
TANTQUE I<=1/P2% FAIRE
SI CPT_N(I)>=P3*MPN
ALORS
Y(N)=LIM_SUP(I)
CPT_NM(N)=CPT_N(I)
N=N+1
SI (N=10) ALORS BREAK
FINSI
I=I+1
FINTANTQUE

//----------------------10/- Tracés

PDS_MAXI=MAX(CPT_NM,N-1)

//Calculer les longueurs proportionnelles aux poids
I=0
TANTQUE I<=N-1 FAIRE
X(I)=CPT_NM(I)*P4/PDS_MAXI
//Afficher "X(I) = " & ctxt$(X(I),2)
I=I+1
FINTANTQUE

//Définir les courbes
L=P4
TANTQUE L>=0 FAIRE
COURBE1(L)=Y(0)*(L<=X(0))
COURBE2(L)=Y(1)*(L<=X(1))
COURBE3(L)=Y(2)*(L<=X(2))
COURBE4(L)=Y(3)*(L<=X(3))
COURBE5(L)=Y(4)*(L<=X(4))
COURBE6(L)=Y(5)*(L<=X(5))
COURBE7(L)=Y(6)*(L<=X(6))
COURBE8(L)=Y(7)*(L<=X(7))
COURBE9(L)=Y(8)*(L<=X(8))
COURBE10(L)=Y(9)*(L<=X(9))
L=L-1
FINTANTQUE

FINSI

PROPRIETES :


Paramètres à définir :
P1=1 : le programme travaille sur les clôtures,
P1=2 : sur les prix moyens,
P1=3 : sur les "typical prices".

P2 : définit en % le seuil de définition des plages.

P3 : définit la fraction des poids des impacts qui sera choisie pour retenir une RS.

P4 : définit le nombre de périodes sur lesquelles sera visualisée la RS de plus grand poids sur le graphe à partir de la FinHisto.

Quelques remarques et illustrations.

Un exemple qui semble fonctionner avec les valeurs de paramètres tels que définis dans la fenêtre "Propriétés" ci-dessus :


On ne peut pas toujours obtenir 4 (ou 6) "résistances", ou 6 (ou 4) supports comme tu le souhaitais.
En effet, si la clôture actuelle est proche d'unn plus haut historique, nous n'aurons d'une ligne "résistance" au dessus : celle qui correspond à la limite supérieure de la page dans laquelle se trouve la dite clôture, c'est à dire la plage la plus haute. C'est le cas pour Pernod-Ricard ci-dessous :


Comme tu peux le constater, j'ai dans ce cas pris la décision d'augmenter le nombre de supports tracés pour obtenir, au maximum, 10 lignes. Ce qui n'est pas toujours possible vu les critères de sélection choisis.
Il existe même des cas dans lesquels 5 droites sont tracées au dessus de la clôture actuelle et 5 en dessous...


Il y aurait encore beaucoup de choses à dire...
Je te laisse le soin de découvrir ce travail et de proposer d'éventuelles améliorations.

Cordialement.

Bonsoir à tous

A l'attention de Smallcaps

Je rentre de déplacement mais comme tu le constateras à l'heure de mon post un passage sur Pro-At est devenu, grâce, nous dirons, pour ne plus être dithyrambique ... à des gens comme toi, un passage obligé.

Quel travail ! !

Je ne pourrais pas le tester avant Samedi, mais je te donnerais dès dimanche après midi, mon sentiment. Semble dors et déjà difficile qu'il soit autre que favorablement impressionné !

Cordialement

bonjour,

je viens de découvrir ce site et je le trouve vraiment formidable
il faut dire que je débute, en parcourant ces pages j'ai découvert pages 30 à 32 de cette file les indicateurs d'ehlers
je viens seulement d'acheter grapheat et de plus la prog n'est pas mon fort

par exemple, sur la ligne suivante, (après copier coller) le soft me dit qu'il y a une erreur de syntaxe au niveau de l'instruction suivante (apparemmment sur le J)

TRENDLINE = 0
J = 0
TANTQUE J TRENDLINE = TRENDLINE + PRIX(J)
J = J+1
FINTANTQUE

merci beaucoup pour vos articles très instructifs

Bonjour Pracos,

Message dans ta bal...
Cordialement.

Bonsoir Pracos,

Effectivement, la bonne version du programme de la TRENDLINE de Ehlers du 15/06/2004, page 30, est la suivante :

//TRENDLINE INDICATOR DE J. EHLERS
//CALCUL DE LA TRENDLINE ET DU FILTRE DE KALMAN
//v 1.0 du 02/06/2004
//

SI RANGHISTO>5
ALORS
PRIX(0)=PERIODE.PRIX
PERIODE = ENTIER(PERIODE.V5)
TRENDLINE = 0
J = 0
TANTQUE J<PERIODE+2 FAIRE
TRENDLINE = TRENDLINE + PRIX(J)
J = J+1
FINTANTQUE
SI PERIODE>0 ALORS TRENDLINE = TRENDLINE/(PERIODE+2)

//Filtre de Kalman 0 lag
//
KALMAN = 0.33*(PRIX + 0.5*(PRIX-PRIX(3))) + 0.67*KALMAN(1)

SI RANGHISTO<26
ALORS
TRENDLINE = PRIX
K = PRIX
FINSI

FINSI

J'ai recopié en rouge l'instruction qui te posait problème puisqu'elle était incorrecte...

Ce qui est étonnant c'est que la version que j'ai postée à l'époque était correcte. Je ne sais pas pourquoi ce changement est intervenu depuis dans le code. Ce n'est d'ailleurs pas la première fois que cela arrive. Serait-ce du au passage au nouveau site?

Comme il n'est plus possible d'accéder aux posts de l'époque pour les corriger, pour être sûrs que tu as bien les versions initialement postées des programmes qui t'intéressent, une solution consisterait à demander à JLR de t'envoyer ses copies Word de l'intégralité de la file. C'est dans sa livraison des post de 2004 que j'ai recopié le bon code du programme.
LONGWAY a réalisé quant à lui un outil sous Excel qui te permet d'accéder aux posts à partir des sujets qui y ont été traités.

Cordialement.

OK merci beaucoup pour ta gentillesse

comment fait-on pour joindre jlr et longway
car apparemment j'ai voulu leur envoyer un message privé mais ils ne sont pas dans la liste

ma question surprendra peut-être quelques uns mais je répéte que je suis nouveau, je ne connais encore pratiquement personne

Bonjour les graphatesiens

J'ai essaye de programmer le Volume Price Confirmation Indicateur tel qu'il est presente dans le dernier "Action Futur" mais le resultat m'est pas identique a l'exemple montré avec l'action lafarge
les valeurs de P1 et P2 sont 50 et 10

MP50(0)=PONDERE(VOLUME(0),P1)
MM50(0)=MOYENNE(VOLUME(0),P1)
VPC(0)=MP50(0)-MM50(0)


MP10(0)=PONDERE(VOLUME(0),P2)
MM10(0)=MOYENNE(VOLUME(0),P2)
VPR(0)=(MP10(0)/MM10(0))*VPC(0)


VM(0)=MM10(0)/MM50(0)

VPCI(0)=VPC(0)*VPR(0)*VM(0)


Quelqu'un connaitrait il un peut plus cette indicateur?
Y aurait il une erreur de programation par rapport à ce qui est indiqué dans action futur?

Bon dimanche

Bonjour crnd,

Je me suis inspiré, pour écrire le programme qui suit, de l'article que Buff Dormeier a publié en février 2005 dans Active Trader Magazine. Je n'ai pas encore lu celui du N°20 d'Action Future sur le sujet.
Ton problème provient, sans doute, du fait que tu emploies le type "pondéré" pour calculer une moyenne qui est en réalité une moyenne "pondérée par les volumes" : VWMA = Volume Weighted Moving Average. C'est un type de moyenne qui pondère chaque prix par le volume de la période correspondante. Avec un recul de calcul de n périodes, la VWMA à chaque période t est définie par :

Comme ce type de moyenne n'est pas disponible sous forme prédéfinie dans GrapheAT Pro, il faut en écrire le programme chaque fois que tu dois l'utiliser.
Elle apparaît 2 fois dans le programme du VPCI qui t'intéresse.

PROGRAMME :

//====
//VPCI
//====

//Volume-Price Confirmation Indicator

//10/09/2006
//V1.0


//----------"Volume Weighted Moving Average" lente
//
SomVol=0
SomPrixVol=0
POUR P1 COURS
SomVol=SomVol+Volume
SomPrixVol=SomPrixVol+Cloture*Volume
FINPOUR
VWMA_Lente=SomPrixVol/SomVol

//----------"Volume Weighted Moving Average" rapide
//
SomVol=0
SomPrixVol=0
POUR P2 COURS
SomVol=SomVol+Volume
SomPrixVol=SomPrixVol+Cloture*Volume
FINPOUR
VWMA_Rapide=SomPrixVol/SomVol

//----------Volume-Price Confirmation/Contradiction
//
VPC=VWMA_Lente-MOYENNE(Cloture,P1)

//----------Volume-Price Ratio
//
VPR=VWMA_Rapide/MOYENNE(Cloture,P2)

//----------Volume Multiplier
//
VM=MOYENNE(Volume,P2)/MOYENNE(Volume,P1)

//----------Volume-Price Confirmation Indicator
//
VPCI=VPC*VPR*VM

//----------VPCI lissé (éventuellement)
//
MVPCI=MOYENNE(VPCI,P3)

Attention, d'après l'article de Dormeieir, il est évident qu'il ne faut pas multiplier VPC par VPR dans l'instruction qui calcule VPC. Ce produit existe uniquement dans le calcul de VPCI...

PROPRIETES :


EXEMPLE : LAFARGE


Pour ceux d'entre-vous qui seraient intéressés par la lecture de l'article de Dormeieir pour aborder en particulier les différentes façons d'utiliser le VPCI, je peux le leur faire parvenir en .pdf par email.

Cordialement.

Merci smallcaps90 pour ton aide

Effectivement action futur ne le presentait pas du tout comme cela....

Je vais essayer tout cela ce soir

Bonsoir à tous,

Bonsoir Smallcaps,

Désolé pour le retard, mais j'avais oublié que nous mettions ce week-end la dernière main aux statuts de notre SCP (société civile de portefeuille) déposé ce matin aux impôts.

En image tes deux derniers travaux sur les droites de soutien et de résistance :
- les droites "Historique", ici en gris, (voir ci-dessus)
- les droites "Actuelles" des plus hauts et plus bas, ici en rouge et vert (voir en page 70).

Comme je l'espérais les premières viennent bien confirmer la validité des secondes !



Comme d'habitude rien à dire. Je vais les travailler cette semaine, et ne manquerais pas de te faire part de tout besoin qui ce se ferait sentir.

Une question comment peut-on récupérer en % la valeur de chacune des SR ?
La réponse est peut-être dans le programme mais je n'ai pas eu le temps d'étudier le code.

Je garde en tête l'idée que l'on doit pouvoir leur donner encore plus d'efficacité en les corrélant à un indicateur type ADX ou ATR.


Bravo, merci et cordialement

PS :
crnd m'a devancé. Je voulais te passer le scan d'Action Future car le pseudo code n'est pas très explicite. Ce scan t'interresse malgré ce ?

PS à SmallCaps

Suis demandeur de l'article de Dormeieir. Merci d'avance.

Cordialement
Dircom13@yahoo.fr