et pour le FUN le résultat mensuel et chose à retenir il est trés rare que les pertes se succédent 2 mois de suite!

Bonsoir max_et_min


Ne t'excuse pas d'intervenir...astucieux ton système.
Une interrogation...
Comme l'indice est calculé de façon pondérée à partir des valeurs du groupe, ne devrait-on pas voir apparaître une "certaine" corrélation? Avec toutes les réserves que l'on doit bien sûr avoir pour un système de croisements de moyennes mobiles qui on le sait n'est pas très performant sans filtre supplémentaire en général.
Pour les valeurs dont la force relative par rapport au CAC40 est orientée dans le bon sens, on devrait espérer pouvoir obtenir d'assez bons résultats. Air France KLM est relativement dans ce cas.
Mais pour celles qui ne le sont pas?
Pourrais-tu nous dire ce qu'il en est pour Carrefour et France Telecom ou encore Lagardère par exemple?

Une autre question...pourrais-tu nous dire ce que tu as choisi comme condition de vente pour obtenir tes résultats?

Cordialement.

Bonsoir smallcaps90
la courbe que je viens de soumettre n'est pas le résultat d'AIR FRANCE et c'est bien là tout l'intérêt c'est un backtesting sur 36 actions sélectionnées pour leur volatilité donc pas toutes du cac40.
il est évident aussi que mon systeme de vente rentre en ligne de compte, mais j'utilise le meme pour le FRAMA donc la comparaison est réaliste.
il est vrai que la formule est simpliste, appliquer une formule style hull serait peut etre judicieux.
je vois que tes essais recoupent les miens Carrefour et France Telecom ou encore Lagardère font parties des plus mauvais résultats
Cordialement

Je croise les résultats mensuels reconstitués et moyennes, annuels etc.. ce qui donne cette petite diffférence par exemple sur air france ici, c'est imparable, mais les croisement sont tellement proche que l'écart n'est qu'une confirmation.
GAIN total brut
Moyenne de la colonne 84,32%

397,55
354,9
303,77
261,03
250,52
230,1 (air france)
228,16
216,23
123,53
106,19
101,99
92,65
90,47
77,93
64,64
57,17
56,43
46,12
44,29
36,17
32,88
32,59
2,12
0
0
-0,48
-3,21
-17,81
-26,93
-29,7
-54,25
-89,61
-132,53
-154,57
Je lance le test 156 actions pour voir.
le résultat reste positif
4,35% de gain annuel moyen sur 11 ans
mais là sur 156 actions il n'y as pas beaucoup d'indicateurs qui y résitent

Le FRAMA reste gagnant 8,98% de moyenne sauf que l'on perdu son capital !!
Bien que si l'on a une vision de ce type nous restons liquide, je dis pas qu'on va pas essayer de temps en temps mais comme c'est chaud et que l'on se brûle on se retire vite
Alors les pointes de pertes ne sont peut être pas forcement toutes effectuées en totalité.
comme dit Régis Laspalès "C'est vous qui voyez "

Attention c'est 12 mois lissés l'entrée pour la hausse n'est pas lorsque la courbe passe zéro mais lorsqu'elle s'inverse même à moins 30%.
Restez calme il n'y a pas d'inversion pour le moment !!
La sortie avant des pertes même chose c'est à l'inversement de la pointe haute qu' il faut être liquide.
Si en plus on améliore cet indicateur ça pourrait devenir intéressant.
Cordialement et bonne journée
GRAPHE SUR 156 Actions

BONJOUR A TOUS
Merci de me dire ou est l'erreur
je n'obtiens pas de reponse avec la stat

j'ai comme indicateur MM et ME
MERCI PAR AVANCE

//DETECTION DES CROISEMENTS ENTRE UNE MOYENNE EXPONENTIELLE
//DE IO PERIODES ER UNE MOYENNE ARITHMETIQUE 30 PERIODES
//
//CHOISIR,NB PERIODES A SCANNER


VAR_SELECT=0
NB_PERIODES=2


POUR NB_PERIODES COURS

SI CROISE(ME10,M30)>0
ALORS
VAR_SELECT=1
COLONNE1 = "ME10 CROISE MM30 A LA HAUSSE LE :" & DATEHISTO$
FINSI

SI CROISE(ME10,MM30)<0
ALORS
VAR_SELECT=1
COLONNE1 = "ME10 CROISE MM30 A LA BAISSE LE :" & DATEHISTO$
FINSI

FINPOUR

SI VAR_SELECT=1
ALORS
SELECTION
FINSI

Bonjour elguapolatino,
Rapidement sans chercher trop à vérifier ton programme une erreur me saute aux yeux.
les variables doivent toujours être informées en premier de la source de ta variable donc par exemple : la variable MME
se trouve par exemple dans le programme MME30
l'appel de ta variable devient donc MME30.MME
demo : a modifier suivant ta source
SI CROISE(MME30.ME10,MME30.M30)>0

Cordialement

Bonjour à tous,
Le programme d'aide vient d'être modifié d'une façon importante.
vous pouvez télécharger la nouvelle version .
maintenant vous pouvez trés facilement faire des essais avec une action pour voir comment vos décisions sont prises, ce qui n'est pas possible avec le programme seul car vous ne pouvez pas consulter la page "Régle" + "Fenêtre d'affichage" il y a un mois par exemple car c'est le dernier jour qui est affiché de base sauf à refaire une grosse programmation de l'ensemble de vos régles.
Donc :
Vous lancez GRAPHAT puis le logiciel d'aide
vous sélectionnez sur ce dernier logiciel l'action que vous voulez tester .
vous supprimez 30 jours ou plus et vous vous placez sur graphat par la touche ALT+TAB
ensuite Touche G entre les deux fléches puis sur le dossier ALL sélectionnez la premiére action '000TEST'
vous testez votre décision à ce jour avec votre "fenêtre d'affichage" et avec la touche ALT+TAB vous changez de logiciel rajoutez 1 journée et ainsi de suite.
sur graphat pour rafraichir aprés changement sur le logiciel d'aide toujours retourner sur G et selectionnez de nouveau 000TEST
Ne pas oublier qu'à chaque clic sur l'action dans le logiciel d'aide réinitialise 000TEST
ça c'est un backtest de votre esprit de décision.
Bonne journée

Bonjour,
Ma contribution en apportant l'indicateur Trend Trigger Factor est à verifier car je n'ai pas tout à fait le même resultat que sur MT4.
(Je suis en cours de programmation pour une 2° version plus efficace)
L'interpretation:
achat si indic<-100 passe au dessus de -100
vente si indic>100 passe en dessou de 100

le programme:

// indicateur Trend Trigger Factor


//| Original Notes and Authors: |
//| Reference := Technical Analysis of Stocks and Commodities, Dec. 2004,p.28. M.H.


//15-day buy power = Highest high of (day 1 to day 15 inclusive) ? Lowest low of (day 16 to day 30 inclusive)

//15-day sell power = Highest high of (day 16 to day 30) ? Lowest low of (day 1 to day 15)

//After calculating these variables, you can move on to calculating the TTF:

//15-day TTF = ((Buy power ? sell power)/(0.5*(Buy power + sell power))) * 100

lignehaut=p2
lignebas=p3


max1=max(cloture,p1) //maxi de 1 a 15 periodes
min1=min(cloture,p1)//mini de 1 a 15 periodes


//maxi de p1 a p1*2
i=p1
max2=Haut(i)
TantQue i<=p1*2 Faire
Si Haut(i)>max2
Alors
max2=Haut(i)
FinSi
i=i+1
FinTantQue
// mini de p1 a p1*2
i=P1
min2=Bas(i)
TantQue i<= 2*P1 Faire
Si Bas(i)<min2
Alors
min2=Bas(i)
FinSi
i=i+1
FinTantQue

buypower=max1 - min2
sellpower=max2 -min1
TTF=(buypower-sellpower)/(0.5*((Buypower + sellpower))) * 100

// fin de code

Voiçi un test avec le dollars australien

Bonjour bamal,
Le TTF a déja été programmé, à priori le tien est dans le bon sens.
L'ancienne version donne l'inverse de ta courbe et en plus lissée.

compte tenu du beau temps!! voici une reprise d'un programme de Smallcaps90.
l'amélioration porte entre autres sur la définiton des hauts et bas pour avoir un programme cohérant sur toutes les actions

//===================
// "Support-Résistance/Volumes"
//===================
//SEUL P3 est utile dans cette version

//INDICATEUR "Support-Résistance/Volumes"
//SR_VOL_MK
//le 09/06/2005
//
A1=min(bas,P3)
A2=max(haut,P3)
INDEX(0)=0
resistance=A2
CL=cloture
SI RANGHISTO=FINHISTO
ALORS

//Cumuler les volumes sur les P3 dernières périodes
I=P3-1
TANTQUE I>=0 FAIRE
SI CLOTURE(I)>=A1 ET CLOTURE(I)<=A2 ET INDEX(I)=0
ALORS
CUMUL=VOLUME(I)
J=I-1
TANTQUE J>=0 FAIRE
SI CLOTURE(I)=CLOTURE(J) ET INDEX(J)=0
ALORS
CUMUL=CUMUL+VOLUME(J)
INDEX(J)=1
FINSI
J=J-1
FINTANTQUE
VCUM(I)=CUMUL
FINSI
I=I-1
FINTANTQUE

//Conserver les 12 plus grands cumuls de volumes
//triés par ordre décroissant
K=1
TANTQUE K<=12 FAIRE
MAXI=MAX(VCUM,P3)
POUR P3 COURS
SI VCUM=MAXI ALORS
C=CLOTURE
VCUM=0
FINSI
FINPOUR
X(K-1)=C //X contient les clôtures des 12 + forts cumuls de volumes
Y(K-1)=MAXI //Y contient les 12 + forts cumuls de volumes, pour info uniquement
SI C<CL et support<C alors support=C
SI C>CL et resistance>C alors resistance=C
K=K+1
FINTANTQUE

//Les 12 courbes
X1=X(0)
X2=X(1)
X3=X(2)
X4=X(3)
X5=X(4)
X6=X(5)
X7=X(6)
X8=X(7)
X9=X(8)
X10=X(9)
X11=X(10)
X12=X(11)

POUR P3 COURS
//en traits forts
COURBE1=X1
COURBE2=X2
COURBE3=X3
COURBE4=X4
COURBE5=X5
COURBE6=X6
//en traits fins
COURBE7=X7
COURBE8=X8
COURBE9=X9
COURBE10=X10
COURBE11=X11
COURBE12=X12
FINPOUR

afficher "Première Résitance/Volumes " & P3 & " Jours à " & ARRONDI(resistance,2) & " Premier Support/Volumes " & P3 & " Jours à " & ARRONDI(support,2)
finsi


//FIN

Bamal
sur ton indicateur, peut tu rajouter directement

// fin de code
si croise(TTF,100)<0 alors FLECHEV=1
si croise(TTF,-100)>0 alors FLECHEA=1

ce qui place les fléches achat et vente.
Avec l'abondance d'indicateur de cette file il est plus facile d'avoir directement à l'écran l'interprêtation
Sur un backtest uniquement sur AIR FRANCE ton indic est meilleur certainement dû aux valeurs utilisées
Bonne journée et bonne programmation

bonjour max_et_min
Merçi,ton travail sur la file avec smallcaps90 est devenu indispensable pour l'évolution de graphat.
pour les signaux d'achat je préfère ceci:
si croise(TTF,100)<0 alors FLECHEV=ttf
si croise(TTF,-100)>0 alors FLECHEA=ttf
Voici la version ameliorèe du ttf sur MT4(indicateur du haut suivre la tendance avec le ttf et suivre le signal avec un sto lent)et la version similaire a graphat en bas.
J'essaie de programmer cette nouvelle version en graphat

Bonsoir à tous
j'ai un probléme avec
//=========
//RS_Histos
//=========

//V2.0
//Permet d'arrêter l'étude à P5 périodes de la FinHisto
//Affiche les résultats numériques
//le 13/09/06

la partie de fin //11
BUG sur PARROT
je cherche j'avance j'ai cerné le bug mais si vous avez le meme bug dites le moi pour savoir si c'est de mon coté ou vraiment de l'indicateur d'origine

42% de baisse RS_Histos n'est pas d'accord, on peut le comprendre mais de là à planter!!!

merci de votre réponse

Bonjour max_et_min


Merci pour le travail de vérification que tu effectues...
Il est très utile car bon nombre de programmes postés sont restés à l'état de prototypes.

Pour ce qui concerne "RS_HISTOS" qui avait été demandé par Débutant13 fin août 2006, puis par Michka qui avait souhaité mi septembre 2006 pouvoir l'utiliser en tout point de l'historique, il y avait effectivement un "vers dans le fruit" dès la première version beta que j'avais postée le 07/09/2006.
Cette version ne prenait d'ailleurs pas en compte tous les souhaits de Débutant13. En particulier, l'algorithme de sélection des R/S à tracer in fine doit pouvoir être amélioré. Si cela te tente n'hésite pas...Sur Parrot il ne trace que des résistances...

Le bug dont tu as décelé justement la présence se trouve au paragraphe "8/- Déterminer le nombre de DIST>=0" de l'ancienne version 2.0.
Celui-ci peut tout simplement être supprimé puisque le nombre de distances >=0 est déjà connu en "7/-" par la variable "NBP" qui y est calculée.
Il suffit de remplacer ensuite la variable K utilisée en "10/- Tracés" du listing de la nouvelle version 3.0, par NBP.

La raison du bug, pour les amis qui seraient intéressés par cet aspect des choses, est que lorsqu'aucune des distances DIST n'est négative entre les limites supérieures des plages de prix et les clotures, la boucle "8/-" plante. Et cela ne se produit pas seulement pour Parrot...
La variable "Cloture" peut être d'ailleurs remplacées par PRIX en "5/-" du listing de la nouvelle version 3.0 ci-dessous si on le souhaite.

J'insiste encore une fois pour préciser que les programmes que je poste sont souvent à l'état de prototypes et que leur utilisation "tels quels" peut poser parfois problème...



//=========
//RS_HISTOS
//=========

//V3.0
//le 03/12/2007

//----------------------PARAMETRES
//P1 : permet de choisir le type de données
//P1=1 : le programme travaille sur les clôtures,
//P1=2 : sur les prix moyens,
//P1=3 : sur les "typical prices".
//P2 : définit en % le seuil de définition des plages.
//P3 : définit la fraction des poids des impacts qui sera choisie pour retenir une RS.
//P4 : définit le nombre de périodes sur lesquelles sera visualisée la RS de plus grand poids sur le graphe à partir de la FinHisto.
//P5 : définit le RangHisto où on souhaite faire l'étude
//----------------------


//Début du code

//----------------------1/- Définition de la limite d'étude
//
LIMITE=FINHISTO-P5

//----------------------2/- Choix du prix
//
MEDIAN_PRICE=(HAUT+BAS)/2
TYPICAL_PRICE=(HAUT+BAS+CLOTURE)/3
PRIX(0)=CLOTURE*(P1=1)+MEDIAN_PRICE*(P1=2)+TYPICAL_PRICE*(P1=3)

SI RANGHISTO=LIMITE
ALORS

//----------------------3- Calculer la droite de régression des 3 dernières clotures
POUR 3 COURS
XR(0) = RANGPOUR
YR(0) = PRIX
FINPOUR
SOMX = SOMME(XR,3)
SOMY = SOMME(YR,3)
SOMXX = SOMME(XR*XR,3)
SOMXY = SOMME(XR*YR,3)
A = (3*SOMXY-SOMX*SOMY)/(3*SOMXX-SOMX*SOMX) //pente régression linéaire

//----------------------4/- Recherche du Plus Haut et du Plus Bas de l'historique
//
ValH=MAX(PRIX,LIMITE)
ValB=MIN(PRIX,LIMITE)

//----------------------5/- Création des numéros des plages et de leurs limites
//
J=0
TANTQUE J<=1/P2%-1 FAIRE //boucle sur les limites des plages
N_Plage(J)=(J+1)
LIM_SUP(J)=ValH-(ValH-ValB)*J*P2%
LIM_INF(J)=ValH-(ValH-ValB)*(J+1)*P2%
DIST(J)=LIM_SUP(J)-PRIX
J=J+1
FINTANTQUE

//----------------------6/- Repèrage des positions des prix par rapport aux plages
//
I=0
TANTQUE I<=LIMITE-1 FAIRE //boucle sur l'historique
J=0
TANTQUE J<=1/P2%-1 FAIRE
SI PRIX(I)<=LIM_SUP(J) ET PRIX(I)>LIM_INF(J)
ALORS
PLAGE_PRIX(I)=LIM_SUP(J)
NO_PLAGE(I)=J+1
FINSI
J=J+1
FINTANTQUE
I=I+1
FINTANTQUE

//----------------------7/- Compter le nombre d'occurence de chaque impact
//
I=0
TANTQUE I<=1/P2%-1 FAIRE //pour chaque plage
CPT=0
J=0
TANTQUE J<=LIMITE-1 FAIRE //pour le n° de plage de chaque prix
SI NO_PLAGE(J)=N_Plage(I)
ALORS
CPT=CPT+1
FINSI
J=J+1
FINTANTQUE
CPT_N(I)=CPT
I=I+1
FINTANTQUE

//----------------------8/- Calculer les moyennes des poids des impacts + et -
//
I=0
TANTQUE I<=1/P2%-1 FAIRE //pour chaque plage
SI DIST(I)>=0
ALORS
P=P+CPT_N(I)
NBP=NBP+1
SINON
N=N+CPT_N(I)
NBN=NBN+1
FINSI
I=I+1
FINTANTQUE
//Moyennes des poids + et -
MPP=P/NBP
MPN=N/NBN

//----------------------9/- Sélectionner les plages à tracer
//Résistances
I=NBP-1
J=0
TANTQUE I>=0 FAIRE
SI CPT_N(I)>=P3*MPP
ALORS
Y(J)=LIM_SUP(I)
CPT_NM(J)=CPT_N(I)
J=J+1
SI (J=6)*(A>=0) OU (J=4)*(A<0) ALORS BREAK
FINSI
I=I-1
FINTANTQUE

//Supports
I=NBP
N=J
TANTQUE I<=1/P2% FAIRE
SI CPT_N(I)>=P3*MPN
ALORS
Y(N)=LIM_SUP(I)
CPT_NM(N)=CPT_N(I)
N=N+1
SI (N=10) ALORS BREAK
FINSI
I=I+1
FINTANTQUE

//----------------------10/- Tracés

PDS_MAXI=MAX(CPT_NM,N-1)

//Calculer les longueurs proportionnelles aux poids
I=0
TANTQUE I<=N-1 FAIRE
X(I)=CPT_NM(I)*P4/PDS_MAXI
I=I+1
FINTANTQUE

//Définir les courbes
L=P4
TANTQUE L>=0 FAIRE
COURBE1(L)=Y(0)*(L<=X(0))
COURBE2(L)=Y(1)*(L<=X(1))
COURBE3(L)=Y(2)*(L<=X(2))
COURBE4(L)=Y(3)*(L<=X(3))
COURBE5(L)=Y(4)*(L<=X(4))
COURBE6(L)=Y(5)*(L<=X(5))
COURBE7(L)=Y(6)*(L<=X(6))
COURBE8(L)=Y(7)*(L<=X(7))
COURBE9(L)=Y(8)*(L<=X(8))
COURBE10(L)=Y(9)*(L<=X(9))
L=L-1
FINTANTQUE

//-----------------------11/- Affichage des résultats numériques
//
Afficher "==============================================="
Afficher NomAction$
Afficher ""
Afficher "Etude à " & ctxt$(P5,0) & " périodes de la FinHisto"
Afficher ""
Afficher "Pente régression = " & ctxt$(A,2)
Afficher ""
I=0
TANTQUE I<=N-1 FAIRE
SI i<=J-1
ALORS
Afficher "Résistance = " & ctxt$(Y(I),2) & " Poids = " & ctxt$(X(I),2)
SINON
Afficher "Support = " & ctxt$(Y(I),2) & " Poids = " & ctxt$(X(I),2)
FINSI
I=I+1
FINTANTQUE

FINSI

//Fin du code

La fenêtre "Propriétés de la règle reste inchangée.


Cordialement.

MERCI max_et_min

cela fonctionne
Amical Marcel